在 Pharo 或 Smalltalk 中创建构造函数

Question

我想在 Pharo 中实现一个小类，所以我这样做了：

Object subclass: #Person
    instanceVariableNames: 'name age'
    classVariableNames: ''
    category: 'Test'

我想模拟一个构造函数，所以我做了一个如下的方法：

newName:aName newAge:aAge
    "comment stating purpose of message"

    name:=aName.
    age:=aAge.
    ^self.

但是当我想从 Pharo 的操场上这样调用它时：

objPerson:=Person newName:'Carl' newAge: 10.

Pharo 无法识别，我做错了什么？

Answer 1

表达式Person newName: 'Carl' newAge: 10 是给类对象Person 的消息。因此，您必须在 Person 的类端实现它。

您的代码需要像这样调整

Person class >> newName: aName newAge: anAge
  | person |
  person := self new.
  person name: aName.
  person age: anAge.
  ^person

请注意，在上面的代码中，self 指的是类，因为方法在类端。但是由于person 是Person 的一个实例，所以消息name: aName 和age: anAge 必须在实例端定义。

因此，在实例端，需要添加两个setter：

Person >> name: aString
  name := aString

Person >> age: anInteger
  age := anInteger

使用这三种方法，您应该能够运行您的示例。

---

关于编码风格的一些额外的 cmets：

首先，我会为“构造函数”方法选择不同的选择器（在 Smalltalk 中，我们将这些称为“实例创建”方法）。例如，

Person class >> named: aString age: anInteger
  ^self new name: aString; age: anInteger

其次，不需要为新创建的实例使用临时的person，因为表达式self new 已经引用了这样的实例。

最后，注意中级联语法的使用

^self new name: aString; age: anInteger

这意味着消息age: anInteger 将被发送到与name: aString 相同的接收者，在这种情况下恰好是self new 返回的新实例。

Answer 2

虽然总的来说我同意 Leandro 的回答，但它将访问器暴露给私有属性。

Kent Beck 在他的 Smalltalk Best Practice Patterns（我强烈推荐）中建议使用 set 作为实例端构造函数的前缀，例如：

"add to class side to 'instance creation' protocol"
Person>>class name: aName age: anAge
    ^ self new
        setName: aName age: anAge;
        yourself

"add to instance side to 'initialization' protocol"
Person>>setName: aName age: anAge
    name := aName.
    age := anAge.

这样您可以控制是否公开属性。

或者你可以坚持原来的命名，只是添加你忘记的new。

objPerson := Person new newName:'Carl' newAge: 10.