在 VBA 中使用 .Find 作为范围

Question

我想沿着一行搜索以找到一个字符串单元格条目“Category 1”并从这一点插入一定数量的列（基于另一个单元格值）。然后，新列应具有“Category 2”、“Category 3”等标签。

到目前为止，我已经设法根据特定的列索引（而不是字符串单元格条目）对其进行编码，以便能够执行上述操作。但是，我一直在尝试对其进行修改，以便可以使用“Category 1”作为列插入的参考点。我下面的代码是我对此的尝试，但出现了“对象不支持此属性或方法”。在 .Find 函数上查看微软的建议页面时，它的代码与我使用的代码非常相似，所以我真的很难理解出了什么问题。

任何帮助将不胜感激！

Sub Add_Column()

    Dim aCount As Integer
    Dim a As Integer
    Dim bCol As Long
    Dim b As Long
    Dim c As Range

    aCount = Range("B12").Value
    bCol = Cells(15, Columns.Count).End(xlToLeft).Column

    With Worksheets(3)
        Set c = .Find("Category 1", LookIn:=xlValues)

        For a = 1 To aCount - 1
            For b = 1 To bCol
                c.Offset(0, 1).Insert Shift:=xlToRight
                Range("G15").Value = "Category" + Str(aCount - a + 1)
            Next b
        Next a
    End With

End Sub

Answer 1

工作表没有Find-方法，范围有。 所以命令应该是这样的：

Set c = .Cells.Find("Category 1", LookIn:=xlValues)

（Cells 是一个 Range，包含工作表的所有个单元格）

我不了解您的代码逻辑的所有细节，但我假设Range("B12") 和Range("G15") 在Worksheets(3) 上？您应该限定所有范围（告诉 Excel 您指的是哪个工作表（否则使用 ActiveSheet，这并不总是您想要的）。并使用 & 进行字符串连接，而不是 +

With Worksheets(3)
    aCount = .Range("B12").Value
    bCol = .Cells(15, .Columns.Count).End(xlToLeft).Column

    Set c = .Cells.Find("Category 1", LookIn:=xlValues)

    For a = 1 To aCount - 1
        For b = 1 To bCol
            c.Offset(0, 1).Insert Shift:=xlToRight
            .Range("G15").Value = "Category" & Str(aCount - a + 1)
        Next b
    Next a
End With

Answer 2

也许这行得通。

Sub x()

Dim aCount, bCol As Long, c As Range, a As Long

With Worksheets(3)
    aCount = .Range("B12").Value
    If Not IsNumeric(aCount) Then Exit Sub
    
    bCol = .Cells(15, .Columns.Count).End(xlToLeft).Column

    Set c = .Cells.Find("Category 1", LookIn:=xlValues)
    If c Is Nothing Then Exit Sub
    
    For a = 1 To aCount - 1
        c.Offset(0, a).Insert Shift:=xlToRight
        c.Offset(0, a).Value = "Category " & a + 1
    Next a
End With

End Sub