用 foldl 剪掉任何东西

Question

我有一个列表 [Maybe a]，我想用一个使用 foldl 的函数来删除 Nothing 元素 例如 cut [Just 2, Just 10, Nothing, Just 5] -> [2,10,5]

I wrote:
cut :: [Maybe a] -> [a]
cut a = foldl (help) [] a
               where help (x:xs) Nothing = (x:xs)
                     help (x:xs) Just a = a:(x:xs)

我的错误在哪里？

Answer 1

通过编写help (x:xs) Nothing = (x:xs)，您使用了(x:xs) 模式，这意味着您希望累加器是一个至少 一个元素的列表。但情况并非总是如此，例如初始累加器[] 是空列表。

我们可以简单地使用变量l，而不是模式：

cut :: [Maybe a] -> [a]
cut a = foldl help [] a
               where help l Nothing = l
                     help l (Just a) = a:l

请注意，您还需要为带参数的构造函数添加括号。

但这不会解决整个模式，现在您将反转列表。这是因为foldl 从左到右遍历列表，因此您在遍历列表时添加了值。我们可以改用foldr。但是现在函数的类型不再起作用，因为foldr 中的help 函数将累加器作为第二个参数。所以我们可以翻转参数：

cut :: [Maybe a] -> [a]
cut a = foldr help [] a
               where help Nothing l = l
                     help (Just a) l = a:l

现在它可以工作了。然而，我们可以稍微清理一下代码。例如，在 cut 函数上使用 eta-reduction：我们可以在函数的头部和主体中删除 a：

cut :: [Maybe a] -> [a]
cut = foldr help []
               where help Nothing l = l
                     help (Just a) l = a:l

并且由于help 中的第二个参数可以被移除，并且可以将主体转换为函数：

cut :: [Maybe a] -> [a]
cut = foldr help []
               where help Nothing = id
                     help (Just a) = (a:)

我们还可以使用另一个变态：foldr 是列表的变态，maybe 是Maybe 的变态，所以我们可以写成：

maybe <value-in-case-of-nothing> <function-just-value> <Maybe value>

所以我们可以将help 重写为：

import Data.Maybe(maybe)

cut :: [Maybe a] -> [a]
cut = foldr help []
               where help = maybe id (:)

或者干脆将它作为foldr的参数注入：

import Data.Maybe(maybe)

cut :: [Maybe a] -> [a]
cut = foldr (maybe id (:)) []

所以现在我们在 catamorphism 中使用了一个 catamorphorhism，所以 catamorphception。