从输入文件填充数组

Question

我是 vb 和一般编码的极端初学者，这是我在这个网站上的第一篇文章。我正在为我正在做的一个项目而碰壁。这是项目中最小的代码块，但所有其他函数将从我要填充的数组中提取。本质上，我需要用代表 .txt 文件中 DVD 价格的数字填充一个数组。 .txt 文件格式如下：

指环王，10.50
阿凡达，5
纽约帮派，7.5
等等

其中 10.50 是我想要分配给 dblPrices(0) 的值。要求不更改 .txt 文件的格式。到目前为止，这是我使用的，但是在测试输出时我得到了 0：

    'Declare variables.
    Dim intCount As Integer = 0
    Dim strLine As String

    'Open the file for input.
    inFile = IO.File.OpenText("availableDVDs.txt")

    'Remove alpha characters from string, assign numeric values to array representing price.
    Do Until inFile.Peek = -1
        strLine = inFile.ReadLine.ToUpper.Replace("[A-Z]", "")
        strLine = strLine.Replace(" ", "")
        strLine = strLine.Replace(",", "")
        Double.TryParse(strLine, dblPrices(intCount))
        intCount += 1
    Loop

这与学校项目有关，所以我不一定要找人为我做我的工作，但也许会为我指明正确的方向。谢谢！

Answer 1

如果您使用List(Of T)（T 代表Type，如Integer 或String 或您自己的类型），那么您不需要像数组一样提前知道大小。此外，您不需要跟踪索引。您可以只使用.Add 方法并将新项目放在列表的末尾。

您可以先使用File.ReadAllLines 从文件中获取数据，这将在文本文件中返回一个行数组。然后您可以在“，”（逗号）上的每一行 .Split 并使用结果数组的第二个元素。双引号中逗号后的小 c 告诉编译器您的意思是这是一个 Char ，它是 .Split 所期望的数据类型。

我使用了Decimal 数据类型而不是Double。与金钱打交道时，使用它来获得您期望的答案会更安全。

在第二个代码示例中，我使用了由字符串前面的 $ 指示的插值字符串。请注意，它与String.Format 非常相似，只是变量直接插入大括号而不是占位符。这在 Visual Studio 2015 及更高版本中可用。

数组方法...

Private Sub OPCode()
    Dim Lines = IO.File.ReadAllLines("availableDVDs.txt")
    Dim Prices(Lines.Count - 1) As Decimal
    Dim index As Integer
    Dim price As Decimal
    For Each line In Lines
        Dim SplitOnComma = line.Split(","c)
        If Decimal.TryParse(SplitOnComma(1), price) Then
            Prices(index) = price
            index += 1
        Else
            MessageBox.Show(String.Format("Price for {0} is not valid.", SplitOnComma(0)))
        End If
    Next
End Sub

列表方法...

Private Sub UsingList()
    Dim Lines = IO.File.ReadAllLines("availableDVDs.txt")
    Dim Prices As New List(Of Decimal)
    Dim price As Decimal
    For Each line In Lines
        Dim SplitOnComma = line.Split(","c)
        If Decimal.TryParse(SplitOnComma(1), price) Then
            Prices.Add(price)
        Else
            MessageBox.Show($"Price for {SplitOnComma(0)} is not valid.")
        End If
    Next
End Sub

选项推断关闭

Private Sub OPCode()
    Dim Lines() As String = IO.File.ReadAllLines("availableDVDs.txt")
    Dim Prices(Lines.Count - 1) As Decimal
    Dim index As Integer
    Dim price As Decimal
    For Each line In Lines
        Dim SplitOnComma() As String = line.Split(","c)
        If Decimal.TryParse(SplitOnComma(1), price) Then
            Prices(index) = price
            index += 1
        Else
            MessageBox.Show(String.Format("Price for {0} is not valid.", SplitOnComma(0)))
        End If
    Next
End Sub