使用VBA循环遍历所有子文件夹[重复]

Question

我正在寻找一个将遍历指定文件夹的所有子文件夹的 VBA 脚本。当我说所有子文件夹时，我的意思是指定文件夹中的每个文件夹，其中的每个文件夹，以及其中的每个文件夹......理论上可能有无限的嵌套子文件夹，但实际上它可能不会超过 3或 4. 我正在使用 VBA Scripting Runtime 对象，因此一旦我循环进入文件夹，我就可以检查一些文件的属性（但我知道如何做这部分）。

感谢您的帮助！

这道题不同于前面题目中列出的“相似”题中包含已知目录的问题，而这里的需要是查找已知目录和未知目录。还需要多层子目录。你们真的应该在启动“重复”之前阅读问题。

Answer 1

只是一个简单的文件夹向下钻取。

sub sample()
    Dim FileSystem As Object
    Dim HostFolder As String

    HostFolder = "C:\"

    Set FileSystem = CreateObject("Scripting.FileSystemObject")
    DoFolder FileSystem.GetFolder(HostFolder)
end  sub

Sub DoFolder(Folder)
    Dim SubFolder
    For Each SubFolder In Folder.SubFolders
        DoFolder SubFolder
    Next
    Dim File
    For Each File In Folder.Files
        ' Operate on each file
    Next
End Sub

Answer 2

为了补充 Rich 的递归答案，一种非递归方法。

Public Sub NonRecursiveMethod()
    Dim fso, oFolder, oSubfolder, oFile, queue As Collection

    Set fso = CreateObject("Scripting.FileSystemObject")
    Set queue = New Collection
    queue.Add fso.GetFolder("your folder path variable") 'obviously replace

    Do While queue.Count > 0
        Set oFolder = queue(1)
        queue.Remove 1 'dequeue
        '...insert any folder processing code here...
        For Each oSubfolder In oFolder.SubFolders
            queue.Add oSubfolder 'enqueue
        Next oSubfolder
        For Each oFile In oFolder.Files
            '...insert any file processing code here...
        Next oFile
    Loop

End Sub

您可以将队列用于 FIFO 行为（如上所示），或者您可以将堆栈用于 LIFO 行为，其处理顺序与递归方法相同（将 Set oFolder = queue(1) 替换为 Set oFolder = queue(queue.Count) 并替换 queue.Remove(1)使用queue.Remove(queue.Count)，并可能重命名变量...）