在 Perl 中覆盖区分大小写的正则表达式答案

【问题标题】：Override case sensitive regex in Perl在 Perl 中覆盖区分大小写的正则表达式
【发布时间】：2015-02-10 14:14:58
【问题描述】：

是否可以覆盖 Perl 中先前定义的正则表达式的区分大小写？例如，如果我有以下内容：

my $upper = qr/BLAH/x;
my $lower = qr/$upper/xi;
warn "blah" =~ $lower

我想在第三行打印一个肯定的匹配。

【问题讨论】：

另一方面，您可以将“blah”设为大写。
不幸的是，我无法控制要搜索的内容。这更像是一个代码重用问题，所以我不必制作两个非常相似的正则表达式来测试大写或小写。

标签： regex perl case-sensitive

【解决方案1】：

您可以将/i 添加到正则表达式中，如下所示：

use re qw( is_regexp regexp_pattern );

sub make_re_case_insensitive {
   my ($re) = @_;

   return "(?i:$re)" if !is_regexp($re);

   my ($pat, $mods) = regexp_pattern($re);
   if ($mods !~ /i/) {
      $re = eval('qr/$pat/'.$mods.'i')
         or die($@);
   }

   return $re;
}

但这不会影响qr/(?-i:BLAH)/。

这更像是一个代码重用问题，所以我不必制作两个非常相似的正则表达式来测试大写或小写。

my $pat = 'BLAH';
my $re1 = qr/$pat/x;
my $re2 = qr/$pat/xi;

【讨论】：

很好的答案，感谢您提供第二条评论。如果字符串中的某些内容是特定于正则表达式的，则它不起作用，例如 \h 字符。所以我的 $pat = 'ABC\hXYZ' 不会匹配 'abc xyz'。如果没有其他情况，我会将其标记为已接受的答案。
@DannySullivan：是的，确实如此。 my $pat = 'ABC\hXYZ' 和 say 'ok' if 'abc xyz' =~ $re2 打印 ok
很棒的电话，很抱歉我错过了。这正是我想要的。