Groovy 范围 - 如何在方法中访问脚本变量

Question

我对 Groovy 中的范围规则有疑问。在下面的 sn-p 中，我有三个变量，a 具有本地范围，b 具有脚本范围，c 也应该使用 @Field 注释获取脚本范围。

#!/usr/bin/groovy
import groovy.transform.Field;

//println org.codehaus.groovy.runtime.InvokerHelper.getVersion()

def a = 42;
b = "Tea"
@Field def c = "Cheese"

void func()
{
    // println a // MissingPropertyException
    println b // prints "Tea"
    println c // prints "Cheese" with groovy 2.1.2, MissingPropertyException with groovy 1.8.6

}

class Main
{
    def method()
    {
        // println a // MissingPropertyException
        // println b // MissingPropertyException
        // println c // MissingPropertyException with both 1.8.6. and 2.1.2
    }

}

func();
new Main().method();

我在 cmets 指示的行上得到 MissingPropertyExceptions。 a 上的异常是预期的，因为该变量具有本地范围。但我希望b 可以在method() 内部访问——它不是。 @Field 在 groovy 1.8.6 中没有做任何事情，尽管升级后它可以工作，所以我猜这是一个老错误。然而，c 在 method() 中是不可访问的。

所以我的问题是：

1. 为什么我不能访问内部带有@Field 注释的变量 method()?
2. 如何在method() 中引用脚本变量？

Answer 1

当您在 groovy 脚本中的 class 声明之外有方法或语句时，会创建一个隐式类。回答您的问题：

1. 在您的示例中，func() 可以访问字段 c，因为它们都是隐式类的成员。 Main 类不是，所以它不能。

2. 您需要将对脚本变量的引用传递给method()。一种方法是传递隐式定义的binding 对象，通过该对象可以访问所有脚本范围变量。

例子：

#!/usr/bin/groovy
import groovy.transform.Field;

//println org.codehaus.groovy.runtime.InvokerHelper.getVersion()

def a = 42;
b = "Tea"
@Field def c = "Cheese"

void func()
{
    // println a // MissingPropertyException
    println b // prints "Tea"
    println c // prints "Cheese" with groovy 2.1.2, MissingPropertyException with groovy 1.8.6

}

class Main
{
    def scriptObject
    def binding

    def method()
    {
        // println a // MissingPropertyException
        println binding.b
        println scriptObject.c
    }
}

func();
new Main(scriptObject: this, binding: binding).method();

Answer 2

此脚本和Main 在同一文件中生成为两个单独的类。

由于Main不是Script类的内部类，所以看不到Script类内部的java.lang.Object c字段。

您要么必须使用static main( args ) 方法（和内部Main 类）将此脚本显式包装在一个类中，要么需要将脚本类的实例传递给方法，例如：Main.method( this )

这是上面脚本生成的那种东西：

class Script032034034 {
  Object c

  Script032034034() {
    c = 'Cheese'
  }

  Object run() {
    Object a = 42
    b = 'Tea'
    func()
    new Main().method()
  }

  void func() {
    println b
    println c
  }
}

class Main {
  Object method() {
  }
}