如何设置 Qml 文本项的行距？

Question

我想不出来这个。我的意思是 Qml 文本项中文本行之间的垂直间距。我不能使用富文本，而且 GridLayout 似乎破坏了我的换行、水平对齐和检查截断的能力。这是在一个矩形内。

Text{   
        width:10
        wrapMode: Text.Text.Wrap
        text:"This will be broken into multiple lines. How could I set the vertical spacing between them?"
     }

我的意思是：

对比

Answer 1

check the documentation 是一个好习惯。浏览它，您可以看到一个名为lineHeight 的属性。我相信这就是你要找的。来自文档：

lineHeight : real

设置文本的行高。该值可以是像素或乘数，具体取决于lineHeightMode。

他们还告诉你如何使用它

默认值为 1.0 的乘数。行高必须为正值。

使用lineHeight 作为乘数，您可以在 MSWord 中模拟以下行间距枚举。

Single
1.5 lines
Double
Multiple

这是一个例子：

import QtQuick 2.0
import QtQuick.Window 2.0

Window {
    visible: true
    width: 200
    height: 300
    
    Text {
        id: text
        width: 175
        anchors.centerIn: parent
        
        //  text: "HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO HELLO"
        text: "Cat ipsum dolor sit amet, sleep nap. You call this cat food. Push your water glass on the floor."
        
        font.family: "Monaco"    // Monaco ❤️
        wrapMode: Text.WordWrap  // Make the text multi-line
        horizontalAlignment: Text.AlignHCenter

        //  lineHeight: 1.0  // single-spacing (default)
        lineHeight: 1.5  // 1.5 line-spacing
        //  lineHeight: 2.0  // double-spacing
        //  lineHeight: 3.0  // triple-spacing
        
    }
}

以下是使用lineHeight 的不同值的结果（在典型的 MacOS 上）

单行距

1.5x、双倍 (2x)、三倍 (3x)

---

但是，如果您想模仿其他行距枚举：

At least
Exactly

您需要修改像素高度。您可以通过将lineHeightMode 设置为Text.FixedHeight 来做到这一点。像这样

Window {
    visible: true
    width: 200
    height: 300
    
    Text {
        id: text
        width: 175
        anchors.centerIn: parent
        
        text: "Cat ipsum dolor sit amet, sleep nap. You call this cat food. Push your water glass on the floor."
        
        font.family: "Monaco"    // Monaco ❤️
        wrapMode: Text.WordWrap  // Make the text multi-line
        
        
        lineHeightMode: Text.FixedHeight
        lineHeight: 6            // exaggerated, text will be scrunched up
        
    }
}

正好 6 个