【问题标题】:Pure pattern matching纯模式匹配
【发布时间】:2017-02-09 15:31:14
【问题描述】:

我正在构建一个函数,该函数计算一个字符在 nth 位置之后出现在字符串中的多次。

countCh ("aaabbbccc", 3, 'b')
val it: int = 2

在C 中,我会使用带有while 循环的累加器。但我正在尝试学习 F# 功能面,不鼓励这种方法。 所以我用警卫来测试几个条件并构建函数:

let rec countCh (s:string, n:int, ch:char) =
match s, n, ch with
   | (s, n, ch) when n > s.Length -> 0                          //p1
   | (s, n, ch) when n < 0 -> 0                                 //p2
   | (s, n, ch) when s.[n] <> ch -> countCh(s, n + 1, ch)       //p3
   | (s, n, ch) when s.[n] = ch -> 1 + countCh(s, n + 1, ch)    //p4

模式3 和4 的共存是有问题的(恐怕不可能)。即使它编译,我也无法让它工作。如何在功能上处理此任务?

【问题讨论】:

    标签: f# pattern-matching


    【解决方案1】:

    首先,这些分支的共存是没有问题的。它们彼此不冲突。为什么你认为它有问题?是因为您收到“不完整的模式匹配”编译器警告吗?该警告并没有告诉您分支冲突,它告诉您编译器无法证明四个分支涵盖了所有可能性。还是你认为有其他原因?如果您希望您的问题得到准确的回答,就必须问得更清楚。

    其次,您正在滥用模式匹配。看:没有图案!每个分支中的模式都完全相同,而且微不足道。只有守卫不同。这在match 中看起来非常违反直觉,但可以用if..elif 简单地表达:

    let rec countCh (s:string) n ch =
       if n >= s.Length || n < 0 then 0
       elif s.[n] = ch then 1 + countCh s (n + 1) ch
       else countCh s (n + 1) ch
    

    注意 1:看看我是如何使参数柯里化的?始终使用柯里化形式,除非有非常充分的理由使用元组。 Curried 参数在调用方使用起来更方便。

    注意 2:您的条件 n &gt; s.Length 不正确:字符串索引从 0 变为 s.Length-1,因此保释条件应为 n &gt;= s.Length。它已在我的代码中更正。

    最后,由于这是一个练习,我必须指出,递归不是尾递归。查看第二个分支(在我的代码中):它递归调用该函数,然后将结果加一。由于您必须对递归调用的结果进行处理,因此递归不能是“tail”。这意味着您在很长的输入上冒着堆栈溢出的风险。

    要将其变为tail 递归,您需要将函数“由内而外”,可以这么说。而不是从每次调用中返回结果,您需要将其传递到 到 每次调用(又名“累加器”)中,并且只从终端情况返回:

    let rec countCh (s:string) n ch countSoFar =
       if n >= s.Length || n < 0 then countSoFar
       elif s.[n] = ch then countCh s (n+1) ch (countSoFar+1)
       else countCh s (n+1) ch countSoFar
    
    // Usage:
    countCh "aaaabbbccc" 5 'b' 0
    

    这样,每个递归调用都是“最后一次”调用(即函数不对结果做任何事情,而是直接将其传递给它自己的调用者)。这称为“尾递归”,可以编译为在恒定堆栈空间中工作(与线性相对)。

    【讨论】:

    • 我认为这是有问题的,因为“不完整的模式匹配”和“索引超出数组范围”错误。我将错误解释为好像“p3”和“p4”会导致两种不同且不兼容的解决方案。
    • 下次,不要犹豫,为您的问题添加详细信息。这样你会得到更准确的答案。
    • 我会的。我什至对你的answer 滥用模式匹配犯规。无论如何,感谢您的回答,它一如既往地直截了当且详尽无遗。你是老师吗? (如果没有,你应该:))
    • 可悲的是,教学 (a) 需要博士学位,而 (b) 的报酬几乎没有。 ;-)
    • @FyodorSoikin 但是所有带薪暑假! :-)
    【解决方案2】:

    我同意其他答案,但我想帮助您解决最初的问题。您需要缩进该函数,并且您有一个错误:

    let rec countCh (s:string, n:int, ch:char) =
        match s, n, ch with
            | s, n,  _ when n >= s.Length-1 -> 0                        //p1
            | s, _,  _ when n < 0 -> 0                                  //p2
            | s, n, ch when s.[n+1] <> ch -> countCh(s, n+2, ch)        //p3
            | s, n, ch when s.[n+1] = ch -> 1 + countCh(s, n+2, ch)     //p4
    

    【讨论】:

    • ...虽然该函数不返回 OP 作为示例的结果?为了显示模式,您可以将一些未使用的变量替换为 _
    • 感谢@AntonSchwaighofer,我看到输入n 是一个基于0 的索引。我已经相应地更新了=)
    • 感谢安东的回答!这对我更好地理解问题很有用。
    【解决方案3】:

    我建议不要自己写,而是向库函数寻求帮助:

    let countCh (s: string, n, c) = 
        s.Substring(n+1).ToCharArray()
        |> Seq.filter ((=) c)
        |> Seq.length
    

    或使用Seq.skip,以及您可以放弃转换为字符数组的事实:

    let countCh (s: string, n, c) = 
        s
        |> Seq.skip (n + 1)
        |> Seq.filter ((=) c)
        |> Seq.length
    

    【讨论】:

    • 这无疑是最实用的方法,但出于教学目的,我想了解如何构建它。
    • 感谢 Anton 提出的解决方案!关于 F# 内置函数,我还有很多东西要学!
    猜你喜欢
    • 1970-01-01
    • 2022-12-04
    • 1970-01-01
    • 1970-01-01
    • 2022-01-11
    • 1970-01-01
    • 1970-01-01
    • 2016-05-17
    • 2022-01-12
    相关资源
    最近更新 更多