Excel VBA - 在工作表中搜索字符串

Question

我有这个 Excel 工作簿，我想在 Sheet1 中搜索特定字符串。如果找到它，请输入一个新值。但是，工作表非常大，所以我认为循环遍历每个单元格不是很有效。那么，我可以搜索一个范围并以这种方式找到它吗？

这是我目前得到的：

Dim rngSearchRange as range

    With ThisWorkbook.Sheets(1)
      Set rngSearchRange = .Range("A2:A" & .Range("A" & Rows.Count).End(xlUp).Row)
    End With

我要查找的字符串是包含三个值的数组中的第一个值。那么，我怎样才能在这个范围内搜索那个特定的字符串，找到位置然后输入一个新值呢？

我在想一些事情：

Dim rngFindRange as range
Set rngFindRange = rngSearchRange.Find(var(0), LookIn:=xlValues, lookat:=xlWhole)

var(0) 是我要查找的数组中的值。但是这条线并没有真正给我任何结果。我离这儿很远吗？

Answer 1

类似的东西

Sub FindMe()
    Dim ws As Worksheet
    Dim rngSearchRange As Range
    Dim rngFindRange As Range
    Dim Var
    Dim elemVar
    Var = Array("apples", "oranges", "fruit")
    Set ws = ThisWorkbook.Sheets(1)
    Set rngSearchRange = ws.Range(ws.[a2], ws.Cells(Rows.Count, "A").End(xlUp))
    For Each elemVar In Var
        Set rngFindRange = rngSearchRange.Find(elemVar, LookIn:=xlValues, lookat:=xlWhole)
        If Not rngFindRange Is Nothing Then
            MsgBox elemVar & " found in " & rngFindRange.Address(0, 0)
        Else
            MsgBox elemVar & " not found in:"
        End If
    Next elemVar
End Sub