在 VBA 宏 excel 中复制值和格式

Question

我对这些东西很陌生，即在 excel 中编写宏。我需要修改一个宏，其中内容从一张纸复制到另一张纸，但这里只复制值，而我也想复制单元格格式。我在许多论坛上搜索并尝试复制它们的格式但仍然没有运气。可能是我在我的代码中遗漏了一些东西。

strActiveSheet - 从中​​复制内容的工作表

res - 粘贴内容的工作表

With Sheets(strActiveSheet)
    .Select
    .Range(.Cells(DataStartRow - 1, 1), .Cells(DataStartRow - 1, 4)).Select
    Selection.Copy
    End With

'Paste
 Sheets(res).Select
 Cells(9, 1).Select
 Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

此代码只是复制值。我尝试使用以下代码但无济于事：

Sheets(res).Select
     Cells(9, 1).Select
     Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    .PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

如果我使用以下代码，这将只是复制格式但省略值：

Sheets(res).Select
         Cells(9, 1).Select
         Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

可能是我认为我没有以正确的格式编写 PasteSpecial 代码。

有人可以帮我在 VBA 中获得用于复制和粘贴值的正确格式以及从一张纸到另一张纸的单元格格式吗？

Darren - 我已经编辑了我的代码并按照您在答案中指定的方式使用：

Dim wrkSht As Worksheet
Set wrkSht = ThisWorkbook.Worksheets("Sheet1")

Dim resSheet As Worksheet
Set resSheet = ThisWorkbook.Worksheets("Demo")

With wrkSht
    .Range(.Cells(DataStartRow - 1, 1), .Cells(DataStartRow - 1, 4)).Copy
End With

With resSheet
    .Cells(9, 1).PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    .Cells(9, 1).PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
End With

但它仍然将数字作为我的单元格的格式，而不是分配给 Sheet1 中单元格的自定义格式。

如果我在这段代码中遗漏了一些东西，你能帮忙吗？

Answer 1

如果您想复制所有内容，您可以在同一命令中复制并粘贴到目标位置。

Sub Test()

    Dim DataStartRow As Long
    DataStartRow = 2

    Dim wrkSht As Worksheet
    Set wrkSht = ThisWorkbook.Worksheets("Sheet1")

    Dim res As Worksheet
    Set res = ThisWorkbook.Worksheets("Sheet2")

    With wrkSht
        .Range(.Cells(DataStartRow - 1, 1), .Cells(DataStartRow - 1, 4)).Copy Destination:=res.Cells(9, 1)
    End With

'    Copy user selection
'    Selection.Copy Destination:=res.Cells(9, 1)

'    Paste to user selection
'    With wrkSht
'        .Range(.Cells(DataStartRow - 1, 1), .Cells(DataStartRow - 1, 4)).Copy Destination:=Selection
'    End With

End Sub

如果你只想要值和单元格格式，那么你可以使用两个 PasteSpecial 命令：

Sub Test()

    Dim DataStartRow As Long
    DataStartRow = 2

    Dim wrkSht As Worksheet
    Set wrkSht = ThisWorkbook.Worksheets("Sheet1")

    Dim res As Worksheet
    Set res = ThisWorkbook.Worksheets("Sheet2")

    With wrkSht
        .Range(.Cells(DataStartRow - 1, 1), .Cells(DataStartRow - 1, 4)).Copy
    End With

    With res
        .Cells(9, 1).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
        .Cells(9, 1).PasteSpecial Paste:=xlPasteFormats
    End With

'    Copy user selection
'    Selection.Copy

'    Paste to user selection
'    With Selection
'        .PasteSpecial Paste:=xlPasteValuesAndNumberFormats
'        .PasteSpecial Paste:=xlPasteFormats
'    End With

End Sub

注意：我没有选择代码中的任何单元格。你只需要引用它们。