从 Excel 在 Outlook 中创建和分配任务

Question

我正在尝试在 Excel 中创建服务台工具，而我想让管理员轻松分配它们的方式是使用 Outlook 中的任务。

管理员将收到电子邮件，在 Excel 中填写一行，然后单击一个按钮在 Outlook 中打开一个新任务，并预先填写字段。然后他们会将电子邮件作为附件拖放。

但是，我正在尝试从电子表格中的值预填充分配给电子邮件地址。分配似乎不起作用，收件人也不起作用。有没有人有任何想法为什么不？这是我到目前为止的代码：

Dim OutApp As Outlook.Application
Dim OutTask As Outlook.TaskItem

 Set OutApp = CreateObject("Outlook.Application")
 Set OutTask = OutApp.CreateItem(olTaskItem)

 With OutTask
    .Assign = Cells(2, "G")
    .Subject = "Service Request" & Cells(2, "A")
    .StartDate = Cells(2, "H")
    .DueDate = Cells(2, "H") + Cells(2, "I")
    .ReminderTime = .DueDate - 1
    .Body = "Please see the attached email for a service request assigned to you."
    .Display
 End With

Set OutTsk = Nothing
Set OutApp = Nothing

End Sub

任何帮助将不胜感激！

Answer 1

在这里查看示例https://msdn.microsoft.com/en-us/library/office/ff869880(v=office.15).aspx 微软提供 分配是一种方法，您像使用属性一样使用它。 收件人是一个集合，所以你必须添加它们，你不能像属性一样分配它们 最后你还有拼写错误的OutTsk。当打开编程Option Explicit 时，我会理所当然地做这件事，这可以防止拼写错误的变量毁了你的一天。

所以尝试这样的事情

Sub tasks()
Dim OutApp As Outlook.Application
Dim OutTask As Outlook.TaskItem

Set OutApp = CreateObject("Outlook.Application")
Set OutTask = OutApp.CreateItem(olTaskItem)
Dim myRecipient As Outlook.Recipient
Set myRecipient = OutTask.Recipients.Add(Cells(2, "C"))
myRecipient.Resolve

 If myRecipient.Resolved Then
    With OutTask
       .Subject = "Service Request" & Cells(2, "A")
       .StartDate = Cells(2, "H")
       .DueDate = Cells(2, "H") + Cells(2, "I")
       .ReminderTime = .DueDate - 1
       .Body = "Please see the attached email for a service request assigned to you."
       .Assign
       .Display
    End With
End If
Set OutTask = Nothing
Set OutApp = Nothing

End Sub