从特定工作表复制未知范围

Question

我正在尝试在 VBA 中进行复制，作为更大宏的一部分，因此它需要在 VBA 中，特定工作表中的未知范围。

如果我在那个工作表中，我有这个代码可以工作：

Sub Copy()
Range("O2", Range("O" & Cells(Rows.Count, "A").End(xlUp).Row)).copy
End Sub()

我有以下适用于特定范围的内容：

Sub Test()
    Worksheets("Data").Range("O2:O10").Copy
End Sub()

如何使第二个代码不具体。

谢谢，

Answer 1

您应该练习始终完全限定您的所有Sheet 和Range 对象。

下面的代码有点长，但最好定义和设置所有对象和变量。

代码

Option Explicit

Sub Test()

Dim Sht As Worksheet
Dim LastRow As Long

' set your worksheet object
Set Sht = ThisWorkbook.Worksheets("Data")

With Sht
    ' get last row in column A
    LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row

    ' copy dynamic range in column O
    .Range("O2:O" & LastRow).Copy
End With

End Sub

Answer 2

最简单和最肮脏的解决方案是这个：

Range("O2:O" & Cells(Rows.Count, "A").End(xlUp).Row).Copy

或者您可以将最后一行隔离为单独的变量：

lastRow = Cells(Rows.Count, "A").End(xlUp).Row
Range("O2:O" & lastRow).Copy

最后，可以决定将要复制的范围声明为单独的变量并使用它，同时声明父工作表：

Public Sub TestMe()

    Dim lastRow As Long
    Dim ws As Worksheet
    Dim rangeToCopy As Range

    Set ws = workshetes("Sheet1")

    With ws
        lastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        Set rangeToCopy = .Range("O2:O" & lastRow)
        rangeToCopy.Copy
    End With

End Sub

更进一步的是使用专用函数来查找每个工作表的最后一行 (GitHub repo here)：

Function lastRow(wsName As String, Optional columnToCheck As Long = 1) As Long

    Dim ws As Worksheet
    Set ws = Worksheets(wsName)

    lastRow = ws.Cells(ws.Rows.Count, columnToCheck).End(xlUp).Row

End Function

Answer 3

在某些时候，您的代码必须知道要复制的范围，对吗？您将其分配给一个变量并使用它。

Option Explicit 

Sub Test()
  Dim startRow as Long
  startRow = 'your method of determining the starting row
  Dim startCol as Long
  startCol = 'your method of determining the starting column
  Dim endRow as Long
  endRow = 'your method of determining the ending row (Last used row would work just fine)
  Dim endCol as Long
  endCol = 'your method of determining the ending column

  With Worksheets("Data")
    .Range(.Cells(startRow, startCol), .Cells(endRow, endCol)).Copy
  End with

End Sub

Answer 4

您可以使用函数将“种子”范围传递给并返回从传递的一个到同一列中最后一个非空单元格的范围，如下所示（cmets 中的解释）

Function GetRange(rng As Range) As Range
    With rng.Parent ' reference passed range parent worksheet
        Set GetRange = .Range(rng, .Cells(.Rows.Count, rng.Column).End(xlUp)) ' return referenced sheet range from passed range to passed range column last not empty cell
    End With
End Function

按如下方式使用：

Sub Test()
    GetRange(Worksheets("Data").Range("O2")).Copy
End Sub

---

您可以增强该功能并让它处理给定的“最终”行

Function GetRange(rng As Range, Optional finalRow As Variant) As Range
    With rng.Parent ' reference passed range parent worksheet
        If IsMissing(finalRow) Then ' if no "final" row passed
            Set GetRange = .Range(rng, .Cells(.Rows.Count, rng.Column).End(xlUp)) ' return referenced sheet range from passed range to passed range column last not empty cell
        Else 'else
            Set GetRange = .Range(rng, .Cells(finalRow, rng.Column)) ' return referenced sheet range from passed range to passed range column cell in give "final" row
        End If
    End With

按如下方式使用：

Sub Test()
    GetRange(Worksheets("Data").Range("O2"), 2).Copy
End Sub

将“final”行保留为可选，该函数可以在有或没有传递的情况下使用：

Sub Test()
    GetRange(Worksheets("Data").Range("O2")).Copy ' this will copy worksheet "Data" range from row 2 down to its column "O" last not empty row
    GetRange(Worksheets("Data").Range("O2"), 3).Copy ' this will copy worksheet "Data" range from row 2 down to row 3
End Sub

Answer 5

你显然不喜欢使用变量，所以：

Worksheets("Data").Range("O2", Worksheets("Data").Range("O" & Cells(Rows.Count, "A").End(xlUp).Row)).copy

足够了。

一般来说，更常见的解决方案是使用 intersect 和 CurrentRegion：

Application.intersect(Worksheets("Data").Range("O2").CurrentRegion,Worksheets("Data").Range("O2:O999999")).copy