将多个工作表保存到单个 pdf？

Question

我正在尝试从工作簿中提取一组工作表；名称包含字符串的工作表：“STRINGY”，并将这些工作表导出为单个 pdf。下面的代码会创建一个空白的 pdf。

Sub Test()
Application.CutCopyMode = False
For Each sht In ActiveWorkbook.Worksheets
    If InStr(1, sht.Name, "STRINGY") > 0 Then
        Sheets(sht.Name).Select Replace:=False
    End If
Next sht
Selection.ExportAsFixedFormat Type:=xlTypePDF, _
    Filename:="C:\File.pdf"

任何帮助将不胜感激。

Answer 1

您的思路是正确的，但没有正确使用Selection。以下应该可以满足您的需要：

Option Explicit

Sub Test()

  Dim arrSheets() As String
  Dim sht As Worksheet
  Dim i As Integer

  i = 0
  For Each sht In ActiveWorkbook.Worksheets
    If InStr(1, sht.Name, "STRINGY") > 0 Then
      ReDim Preserve arrSheets(i)
      arrSheets(i) = sht.Name
      i = i + 1
    End If
  Next sht

  ThisWorkbook.Sheets(arrSheets).Select

  ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
                                  Filename:="C:\File.pdf", _
                                  OpenAfterPublish:=True

End Sub

基本上，您需要将名称包含您的搜索字符串的工作表添加到一个数组中，并同时选择它们。然后使用该选择作为导出为 PDF 的基础。

我添加了OpenAfterPublish 导出选项，以便导出后文件在您的 PDF 阅读器中打开；这不是必需的。

上述代码已在 Excel 2010 中成功测试，但不能确定它是否可以在 Excel 2007 或更早版本中运行。请注意，如果当前未安装 PDF 插件，则会出现错误。如果是这种情况，您可以在 http://www.microsoft.com/downloads/details.aspx?familyid=4d951911-3e7e-4ae6-b059-a2e79ed87041 找到它。