ListView 控件 Windows API - CheckAll - CheckCount？

Question

我有一个 VB6 项目，我正在从使用 ListBoxes 切换到使用 ListViews。列表具有复选框样式。我正在寻找要发送到 ListView 的 Windows API 消息，这些消息指定：

• 全部勾选
• 取消选中所有
• 检查计数

这对于 ListBox 来说很容易，因为 Selected 与 Checked 是一样的。 ListView 不是这样。

除了 CHECKED not SELECTED 之外，其他类似的东西：

Private Const LVM_FIRST As Long = &H1000
Private Const LVM_GETITEMCOUNT As Long = (LVM_FIRST + 4)
Private Const LVM_GETSELECTEDCOUNT As Long = (LVM_FIRST + 50)
Private Const LV_SETSEL = &H1000 + 43

Private Function ListViewSelectedCount(ByRef LV As ListView) As Long
    ListViewSelectedCount = SendMessage(LV.hwnd, LVM_GETSELECTEDCOUNT, 0, 0)
End Function

Private Sub ListViewSelectAll(ThisBox As ListView)
    Dim LV As LV_ITEM
    LV.mask = &H8
    LV.State = True
    LV.stateMask = &H2

    Call SendMessage(ThisBox.hwnd, LV_SETSEL, ByVal -1, LV)
End Sub

我确实找到了 ListView 消息列表：http://vbnet.mvps.org/index.html?code/comctl/lvmembers.htm 但似乎没有什么是我需要的。

Answer 1

您是否有理由必须使用 Windows API 消息来设置选定标志。我假设您正在使用 Microsoft Windows 公共控件中的 ListView。如果你是，那么你可以使用以下代码：

Public Sub SetSelected(ByVal blnCheck As Boolean)
Dim lviItem As ListItem

    For Each lviItem In ListView.ListItems
        lviItem.Checked = blnCheck
    Next

    Set lviItem = Nothing

End Sub

Public Function CountChecked() As Long
Dim lngCount    As Long
Dim lviItem     As ListItem

    For Each lviItem In ListView.ListItems
        If lviItem.Checked Then
            lngCount = lngCount + 1
        End If
    Next

    Set lviItem = Nothing

    CountChecked = lngCount

End Function

使用 true 或 false 调用 SetSelected 并将全选/取消全选，第二个函数将返回计数。您应该将代码的 ListView 位重命名为您的 ListView 的名称。如果你想让它更通用，你可以将 listview 传递给 sub 和 function，代码看起来像这样：

Public Sub SetSelected(ByRef lvwToChange As ListView, ByVal blnCheck As Boolean)
Dim lviItem As ListItem

    For Each lviItem In lvwToChange.ListItems
        lviItem.Checked = blnCheck
    Next

    Set lviItem = Nothing

End Sub

Public Function CountChecked(ByRef lvwToCount As ListView) As Long
Dim lngCount    As Long
Dim lviItem     As ListItem

    For Each lviItem In lvwToCount.ListItems
        If lviItem.Checked Then
            lngCount = lngCount + 1
        End If
    Next

    Set lviItem = Nothing

    CountChecked = lngCount

End Function

希望这会有所帮助。