通过 Nat-kind 重叠实例答案

【问题标题】：Overlapping instances via Nat-kind通过 Nat-kind 重叠实例
【发布时间】：2019-01-02 02:42:03
【问题描述】：

这个问题实际上是由于尝试将几个数学组实现为类型而出现的。

循环组没有问题（Data.Group 的实例在别处定义）：

newtype Cyclic (n :: Nat) = Cyclic {cIndex :: Integer} deriving (Eq, Ord)

cyclic :: forall n. KnownNat n => Integer -> Cyclic n
cyclic x = Cyclic $ x `mod` toInteger (natVal (Proxy :: Proxy n))

但是对称群在定义一些实例时存在一些问题（通过阶乘系统实现）：

infixr 6 :.

data Symmetric (n :: Nat) where
    S1 :: Symmetric 1
    (:.) :: (KnownNat n, 2 <= n) => Cyclic n -> Symmetric (n-1) -> Symmetric n

instance {-# OVERLAPPING #-} Enum (Symmetric 1) where
    toEnum _ = S1
    fromEnum S1 = 0

instance (KnownNat n, 2 <= n) => Enum (Symmetric n) where
    toEnum n = let
        (q,r) = divMod n (1 + fromEnum (maxBound :: Symmetric (n-1)))
        in toEnum q :. toEnum r
    fromEnum (x :. y) = fromInteger (cIndex x) * (1 + fromEnum (maxBound `asTypeOf` y)) + fromEnum y

instance {-# OVERLAPPING #-} Bounded (Symmetric 1) where
    minBound = S1
    maxBound = S1

instance (KnownNat n, 2 <= n) => Bounded (Symmetric n) where
    minBound = minBound :. minBound
    maxBound = maxBound :. maxBound

来自 ghci 的错误消息（仅简短）：

Overlapping instances for Enum (Symmetric (n - 1))
Overlapping instances for Bounded (Symmetric (n - 1))

那么GHC怎么知道n-1是否等于1呢？我也想知道没有FlexibleInstances能不能写出解决方案。

【问题讨论】：

标签： haskell math gadt data-kinds overlapping-instances

【解决方案1】：

添加 Bounded (Symmetric (n-1)) 和 Enum (Symmetric (n-1)) 作为约束，因为完全解决这些约束需要知道 n 的确切值。

instance (KnownNat n, 2 <= n, Bounded (Symmetric (n-1)), Enum (Symmetric (n-1))) =>
  Enum (Symmetric n) where
  ...

instance (KnownNat n, 2 <= n, Bounded (Symmetric (n-1))) =>
  Bounded (Symmetric n) where
  ...

为了避免FlexibleInstances（IMO 不值得，FlexibleInstances 是良性扩展），请使用 Peano 数字 data Nat = Z | S Nat 而不是 GHC 的原始表示。先将实例头Bounded (Symmetric n)替换为Bounded (Symmetric (S (S n')))（这起到约束2 <= n的作用），然后用一个辅助类（可能更多）分解实例以满足对实例头的标准要求。它可能看起来像这样：

instance Bounded_Symmetric n => Bounded (Symmetric n) where ...
instance Bounded_Symmetric O where ...
instance Bounded_Symmetric n => Bounded_Symmetric (S n) where ...

【讨论】：