Julia 中数组的并行操作

Question

此代码在 Julia 中的并行（跨多个 CPU）版本是什么？

V = zeros(3)
for i = 1:100000
    cc = rand(1:3)
    V[cc] += 1
end

Answer 1

这是对循环的直接重写，它是线程安全的，并且避免了错误共享：

using Random
using Base.Threads

V = let
    mt = Tuple([MersenneTwister() for _ in 1:nthreads()])
    Vv = Tuple([zeros(3) for _ in 1:nthreads()])
    @threads for i = 1:100000
        @inbounds cc = rand(mt[threadid()], 1:3)
        @inbounds Vv[threadid()][cc] += 1
    end
    reduce(+, Vv)
end

但是，一般来说，对于这么小的工作，使用线程可能不会给您带来太多好处。此外，如果您确实需要性能，则可能应该对代码进行一些重组，例如像这样：

function worker(iters, rng)
    v = zeros(3)
    for i = 1:iters
        cc = rand(rng, 1:3)
        v[cc] += 1
    end
    v
end

V = let
    mt = Tuple([MersenneTwister() for _ in 1:nthreads()])
    Vv = [zeros(3) for _ in 1:nthreads()]
    jobs_per_thread = fill(div(100000, nthreads()),nthreads())
    for i in 1:100000-sum(jobs_per_thread)
        jobs_per_thread[i] += 1
    end
    @assert sum(jobs_per_thread) == 100000
    @threads for i = 1:nthreads()
        Vv[threadid()] = worker(jobs_per_thread[threadid()], mt[threadid()])
    end
    reduce(+, Vv)
end

同样在 Julia 1.3 下，您不必手动管理 MersenneTwister，因为 Julia 将为每个线程创建单独的 PRNG。