使用ods excel语句时停止Excel转换保存为字符的数字

Question

我需要将一些结果从 SAS 导出到 Excel。到目前为止，我为此使用了一个简单的proc export，但由于导出变得更加复杂（多个proc results 和data sets 需要映射到一张表），我需要找到一个替代方案。 看来，ods excel 是要走的路——我同意，它是高度可定制的——但我面临一个问题，我不确定它是否与 SAS 或 Excel 相关。

问题：

当我有一个带有字符列的 SAS 数据集时，其中数据是由点分隔的数字字符串，ods export 到 Excel 将始终将此数据转换为数字格式，这基本上使数据不可读。例如：

character in SAS "04.2000" will become "4,2" in Excel (Standard format)

MWE：

data test;
input date $;
datalines;
04.2000
10.2001
; 

ods excel file="date.xlsx";
proc print data=test;
run;
ods excel close;

proc 导出正确打印此数据，无需自动转换。这是 SAS 还是 Excel 方面的东西？使用ods excel 时，我该怎么做才能获得与proc export 相同的结果，有什么想法吗？

Answer 1

要绝对强制<month>.<year> 日期表示值成为 Excel 中的字符串，请将其呈现为公式。即使在“null”编辑单元格 (F2,Enter) 之后，该值也不会改变。

例子：

data test;
input datestring $;
forcedate = '="' || datestring || '"';
datalines;
04.2000
10.2001
; 

ods excel file="date.xlsx";
proc print data=test;
run;
ods excel close;

您可以将$CHAR<n> 格式应用于您的日期字符串。如果您手动编辑单元格，该字段在 Excel 中仍将被解释为数字。

例子：

data test;
input datestring $;
format datestring $char7.;
datalines;
04.2000
10.2001
; 

ods excel file="date.xlsx";
proc print data=test;
run;
ods excel close;

Excel（图片）

您还可以使用 ODS EXCEL 样式选项tagattr='type:String' 强制初始单元格呈现，但是在编辑时（F2、Enter）Excel 将再次对单元格值进行数字化。

例子：

proc print data=test;
  var datestring / style=[tagattr='type:text'];

* String also works;
* var datestring / style=[tagattr='type:String'];
run;

Answer 2

例如，您可以使用格式。它工作正常：

data test;
input date $;
datalines;
04.2000
10.2001
; 
run;
ods excel file="c:\temp\date.xlsx";
proc print data=test;
format date $20.;
run;
ods excel close;

Answer 3

如果您使用 PROC REPORT，您可能可以通过您的 DEFINE 语句执行此操作。

define date/ 'Date' format = $20.  style(column)=[tagattr="type:text"];