SAS 计算 excel 观察值

Question

我必须对大约 500 个 excel 文件的一些 excel 文件进行帐户对帐。

我不需要按文件只匹配帐号。

Example file 1: \\directory\Loaded\Jan2014\excel1

Example file 2: \\directory\Loaded\Feb2014\excel2

Example file 3: \\directory\Loaded\Feb2014\excel3

（帐号始终填写在 B 列中，第 1 到第 5 行作为标题）

使用上述示例所需的输出：

主文件夹（文件）|子文件夹 (Jan2014) |文件名 (excel1) |帐号计数

这可以使用 SAS 吗？

因此，如果这还不够信息，我已经在网上搜索并找到了使用批处理文件带回文件列表的方法，但没有什么可以计算观察结果。

Answer 1

SAS 解决方案是这样的。如果你做了所有的 libnames 然后设置所有的数据集，你可以让它更有效率，但是这段代码更容易一些，对于 500 我认为这是合理的。不幸的是，excel libnames 似乎不会为您计算行数，因此您不能只使用 dictionary.tables 来执行此操作。

如果工作表名称不同，您需要修改它以考虑到这一点，方法是设置一个宏变量来保存工作表名称（如果它以某种方式链接到文件名），或者通过宏查询 dictionary.tables 以查看 libname 中存在哪些表。

%let basedir=c:\temp;  *whatever the base directory is that all of your excel files are upstream from;
filename dirl pipe "dir /b/s &basedir.\*.xlsx";

data libnames;
infile dirl lrecl=1024 pad;
input
@1 filename $1024.;
run;

%macro get_rowcount(file=);
  libname _temp excel "&file.";
  data _rowcount;
  set _temp."Sheet1$"n end=eof;
  length file_name $1024;
  retain file_name "&file.";
  if eof then do;
    rowcount=_n_;
    output;
  end;
  keep rowcount file_name;
  run;

  proc append base=rowcounts data=_rowcount force;
  run;
%mend get_rowcount;

proc sql;
select cats('%get_rowcount(file=',filename,')') into :sheetlist separated by ' '
  from libnames;
quit;
&sheetlist.;

Answer 2

我会为此使用 Powershell，除非您确实需要在 SAS 中执行此操作。 要将结果获取到 SAS，如果需要，您可以将数据从 powershell 保存到 excel 文件并导入到 SAS。

看看例如Get the Number of Rows in Column of a worksheet 作为首发。