SAS - sgplot - 每组设置透明度答案

【问题标题】：SAS - sgplot - setting transparency per groupSAS - sgplot - 每组设置透明度
【发布时间】：2015-09-24 07:41:12
【问题描述】：

在下面的示例中，我想让第 1 组中的数据透明（透明度 = 选项），并让第 2 组中的数据保持原样。你能帮帮我吗？

data dat;
    input group $ x y;
    datalines;
    1 0.5 2
    1 0.8 1
    1 1   2.2
    2 4.3 5
    2 0.7 2
    ;
run;

proc sgplot data=dat;
    scatter x=x y=y / markerattrs=(symbol=circlefilled size=8); 
run;

【问题讨论】：

@akrun: 抱歉，处理不正确...现在我无法检索并重新打开它:-(
没问题，只是为了未来。有人可能会从保持开放中受益。
@akrun：有没有办法重新打开它？
您可以点击重新打开按钮，

标签： graph sas

【解决方案1】：

在 SAS 9.4 TS1M1 及更高版本中，这可以通过使用属性映射来实现。

data dat;
    input group $ x y;
    datalines;
    1 0.5 2
    1 0.8 1
    1 1   2.2
    2 4.3 5
    2 0.7 2
    ;
run;

data group_attrmap;
    ID="groups";
    value=1;
    markercolor="cxFF0000";
    markertransparency=0.5;
    output;
    value=2;
    markertransparency=0;
    output;
run;

proc sgplot data=dat dattrmap=group_Attrmap;
    scatter x=x y=y / markerattrs=(symbol=circlefilled size=8) group=group attrid=groups;
run;

在此之前，由于不支持MARKERTRANSPARENCY，最好的办法是有两个单独的图 - 一个用于第 1 组，一个用于第 2 组，并带有单独的透明胶片。您可以通过将 x/y 拆分为两组列来做到这一点，并且对于缺少 x/y 的另一组（然后不绘制点）。

在这个特定的示例中，您也可以使用注释来绘制它，因为注释散点图只是在现有数据集上设置正确变量的问题。

【讨论】：