如何动态加载 Perl 模块并使用它们的功能？

Question

我正在尝试将我的代码中的一些 use 语句切换到 require 用于仅在满足某些条件时才使用的模块（例如，程序可能在需要这些模块的时间之间加载 1,000 次），以便降低开销并提高我的程序的执行速度（我一直在使用 Devel::NYTProf 来分析我的代码，并且即使我在某个会话中没有使用它们，一些模块也会增加显着的执行时间）。

我遇到了一个问题，即脚本在加载时终止，因为未定义符号（在导入该模块之前不会定义符号）。有没有办法告诉 Perl 符号将在运行时导入？一个简单的例子：如果我调用一个触发它的例程，我只想使用 Data::Dumper：

sub dataDumper {
    require Data::Dumper;
    Data::Dumper->import;
    say STDERR Dumper @_;
}

但是，在第三行调用 Dumper 会导致异常。我可以通过参考Data::Dumper->Dump 来解决这个问题。然而，与 LWP::UserAgent 类似的问题证明有点麻烦，因为 LWP::UserAgent 导入 HTTP::Request。我还没有想出避免抛出异常的my $request = new HTTP::Request GET => $params->{'url'}; 的变体。

假设我可以这样做，有什么理由说明这种方法是个坏主意吗？由于在编译时不加载这些模块，我是否会失去任何类型的优化？在像 LWP 这样的模块上，这似乎是一个简单的调用——我只是不怎么使用它。我对是否尝试在（例如）Text::Textile 和 Text::MultiMarkdown 之间动态切换有点困惑（我通常每次执行只需要一个。

Answer 1

在子调用中，参数周围的括号只能为声明的子省略。

say STDERR Dumper(@_);

请注意，您以这种方式加载的 subs 上的原型将被忽略。

---

第二行没有问题，因为它不涉及子调用。方法调用不受影响。

$ perl -M5.010 -e'
   if ($ARGV[0]) {
      require LWP::UserAgent;   # or HTTP::Request
      my $request = new HTTP::Request GET => "https://stackoverflow.com";
   }

   say "ok";
' 0
ok

$ perl -M5.010 -e'
   if ($ARGV[0]) {
      require LWP::UserAgent;   # or HTTP::Request
      my $request = new HTTP::Request GET => "https://stackoverflow.com";
   }

   say "ok";
' 1
ok

因此，类模块在这里特别有用。考虑复杂情况下的插件模型。

---

如果在编译时不加载这些模块，我是否会失去任何优化？

常量需要替换较慢且不能折叠的函数调用。

$ perl -MO=Concise,-exec -M5.010 -e'
   use constant FOO => 2;
   say 2 + FOO;
'
...
2  <;> nextstate(main 188 -e:3) v:{,fea=1
3  <0> pushmark s
4  <$> const[IV 4] s/FOLD
5  <@> say vK
...

$ perl -MO=Concise,-exec -M5.010 -e'
   say 2 + FOO();
   require constant; import constant FOO => 2;
'
...
2  <;> nextstate(main 2 -e:2) v:{,fea=1
3  <0> pushmark s
4  <$> const[IV 2] s
5  <0> pushmark s
6  <#> gv[*FOO] s/EARLYCV
7  <1> entersub[t2] sKS/TARG
8  <2> add[t3] sK/2
9  <@> say vK
...

Answer 2

使用完全限定名称，不要导入任何内容。

sub dataDumper {
    require Data::Dumper;
    say STDERR Data::Dumper::Dumper(@_);
}

但是，由于 LWP::UserAgent 导入了 HTTP::Request，因此 LWP::UserAgent 的一个类似问题有点棘手。

此声明中的术语是错误的。 LWP::UserAgent 不导入任何东西。事实上，它根本没有import 方法。它加载 HTTP::Request，通过useing 它。因此 perl 将在 LWP::UA 为 required 时切换到编译时间，编译它，并将 HTTP::Request、HTTP::Response 和 HTTP::Date（以及其他一些）、all explicitly without importing anything 加载到LWP::UserAgent 的命名空间。

$request = new HTTP::Request GET => $params->{'url'};

如果尚未加载 HTTP::Request，我将无法重现此爆炸。不执行就不会出错。

if (0) {
    HTTP::Request->new(GET => '/foo');
    new HTTP::Request GET => '/foo';
}

这很好。你当然应该使用第一种形式，而不是间接对象表示法，因为它是模棱两可的，但没有区别。

如果您要使用HTTP::Request::Common，它导入GET 和POST 等以快速生成HTTP::Requests，您也可以在运行时只使用require，然后使用完全限定名称。

if ($make_web_request) {
  require LWP::UserAgent;
  require HTTP::Request::Common;

  my $ua = LWP::UserAgent->new;
  $ua->request(HTTP::Request::Common::GET('https://example.org'));
}

如果在编译时不加载这些模块，我是否会失去任何优化？

没有。如果您的代码启动了很多次，并且经过了很多不同的路径，那么只有在您需要它们时才加载它们是完全可以的。它几乎没有真正的区别。 Perl 无论如何都会在每个require 的编译时间和运行时间之间切换。一般来说，这根本不是惩罚。

Answer 3

我做类似的事情，但像这样。即使require 不会再次加载它，state 也会以某种方式使其更快：

sub something {
    state $rc = require Foo;
    ...
    }

如果我想导入东西

sub something {
    state $rc = do { require Foo; Foo->import };
    ...
    }

记住use 的实际含义：

BEGIN {
    require Foo;
    Foo->import(...);
    }

BEGIN 仅在编译时执行此操作。如果您稍后执行所有相同的步骤，您最终会在同一个地方（稍后）。