如何在 RedHat 上仅使用核心 Perl 打印变量及其值？

Question

我正在尝试在 Perl 中创建一个简单的小子，最好不要使用标准 RedHat linux 发行版中没有的任何模块。换句话说，越便携越好，因为我不能总是控制我在哪个系统环境中工作。明显的问题是将变量传递给子例程，以便可以使用原始变量名称和值。我可以得到一个或另一个，但如果没有更复杂的 sub 调用输入，我无法弄清楚如何做到这两个，如下所示。我可以传递一个字符串和一个引用，但这几乎就像用一个简单的本地打印它一样混乱：

print "\$A = $A\n"; 

也存在潜在的范围问题，但一步一步来。我现在在想，也许这不是那么简单。

（是的，这是我正在寻找的绝对懒惰的程序员代码）

示例伪代码：

my $A = 1;
my $secondVar = "something new";
my $XXX = 12345;

# Print a listing of the variables of interest in a nice easy to read listing
# with a minimum of typing. 

printVars( $A, $secondVar, $XXX ); 

# Note I could settle for passing by reference \$A but no more complicated than this in
# the sub call. This is just a little utility sub to use to double check variables while
# coding something new.

输出：

$A = 1
$secondVar = something new
$XXX = 12345

一个粗略的 SUB：

sub printVars {
    my @ListOfVars = @_;
    my $i;
    my ($theVarName, $theVarValue);

    for( $i=0; $i<@ListOfVars; $i++) {
       $theVarName = ??;  # This is where things break down.
       $theVarValue = $ListOfVars[$i];
       print "$theVarName = $theVarValue\n";
    }
}

感谢您提供的任何帮助..

享受.. --布莱恩

Answer 1

如果 Paul Tomblin 和 john 建议的使用变量名的方法是可以接受的，您可能需要引入 Data::Dumper 模块以便能够打印出数据结构。

Data::Dumper 长期以来一直是标准 Perl5 发行版的一部分（我刚刚在 CPAN 上验证它已经在 5.6、5.8 和 5.10 中）。如果您的操作系统供应商没有以奇怪的方式将其分解，则无需担心Data::Dumper 不存在。

Answer 2

感觉就像你在这里重新发明轮子一样，所以我不得不问你的动机。有很多现有的机制可以帮助您调试代码，包括内置调试器（参见 perldoc perldebug 和 perldoc perldebugtut 以获取手册和教程），以及位于 CPAN 的巨大模块库。作为初学者，您正在考虑构建的任何东西都已经构建，因此除非您只是将其作为一种学习体验，否则您应该使用您已经可用的工具。

Data::Dumper 和Data::Dump 是查看变量内部的常用方法，不仅是您现在编码的简单字符串，还包括深度和复杂的数据结构。 Data::Dumper 是许多标准 Perl 安装的一部分，但 CPAN 上分发的任何内容都可以安全地依赖，因为它可以轻松安装在您可能遇到的任何系统上。

Answer 3

我认为不借助 PadWalker 就无法对词法变量执行此操作，因此您可能需要安装它。假设您可以，这里有一个可行的解决方案，它允许使用最少的调用站点语法。

use PadWalker qw/peek_my peek_our/;
use Data::Dumper;
$Data::Dumper::Indent = 0; # or however pretty you want

sub inspect {
    my $my  = peek_my  1;
    my $our = peek_our 1;

    for (split(/\s+/ => "@_")) {
        my $val = $$my{$_} || $$our{$_} 
                           || die "$_ not found";
        print Data::Dumper->Dump(
            /^\$/ ? ([$$val], [$_])
                  : ([ $val], ['*' . substr $_, 1])
        ) . "\n";
    }
}

sub foo {
    my $bar = shift;
    inspect '$bar';
}

{ # closed scope
    my $x = 'hello, world!';
    my $y;
    my @z = 1 .. 10;
    our %global = (a => 1, b => [1 .. 3]);
    my $ref = \%global;

    inspect '$x $y @z %global $ref';  # qw/.../ can be used also
    foo;
    foo $x;
}

打印出来

$x = 'hello, world!';
$y = undef;
@z = (1,2,3,4,5,6,7,8,9,10);
%global = ('a' => 1,'b' => [1,2,3]);
$ref = {'a' => 1,'b' => [1,2,3]};
$bar = undef;
$bar = 'hello, world!';

Answer 4

您可以将变量名称作为标量传递，然后使用引用来打印出值。来自 perlref：

1.  $name = "foo";
2. $$name = 1; # Sets $foo
3. ${$name} = 2; # Sets $foo
4. ${$name x 2} = 3; # Sets $foofoo
5. $name->[0] = 4; # Sets $foo[0]
6. @$name = (); # Clears @foo
7. &$name(); # Calls &foo() (as in Perl 4)
8. $pack = "THAT";
9. ${"${pack}::$name"} = 5; # Sets $THAT::foo without eval

Answer 5

有关使用变量作为变量名的观点，请参阅How can I use a variable as a variable name?。否则，您必须按照 john 和 Paul Tomblin 的建议使用引用。

Answer 6

传入一个变量名列表，然后用

打印出来

foreach $varname (@list)
{
   print "$varname = $$varname\';
}

实际上，想想看，这也行不通，因为 $$ 行不通，因为 sub 不知道该变量。我不认为你能做你想做的事，除了将所有变量名和值放入一个散列并用 Data::Dumper 转储它们。通常此时我会删除这个答案，但其他几个人已经引用了它，所以我不会。

use Data::Dumper;
print Dumper({"a" => $a, "cVar" => $cVar});

会产生类似的东西：

$VAR1 = {
          'a' => 'foo',
          'cVar' => 'this is cVar'
        };

Answer 7

没有子，但我推荐Smart::Comments。就这么简单：

use Smart::Comments;
### $A

$A 将在其全部荣耀中显示，如果 1) 它没有动态循环（如某些 Win32::OLE 对象那样），或者如果 2) 它不是“由内而外的对象”，即是指向数据键的指针，而不是数据本身。输出比Data::Dumper 更具可读性（它在幕后使用Data::Dumper，因此可以使用DD 全局变量，例如$Data::Dumper::Deparse（位于链接列表的底部），用于打印出subs。

当您不想打印内容时，只需将use 语句注释掉即可。那么，他们只是cmets。

它也很便携。我只是将 Text::Balanced 和 Smart::Comments 从我的 PC 移植到 AIX 机器上，瞧。完成。

Answer 8

# A sub to print the value of any variable, scalar, array, or hash
sub strv
{ # edit structured things as a string for debugging
  my ($v,$d) = @_;
  my $s = '';

  $d = 0 if not defined $d;

  if (not defined $v)
  {
    $s.= (' 'x$d)."N";
  }
  elsif (ref($v) eq 'SCALAR')
  {
    if (! defined $$v)
    {
      my $null = 'NULL';
      $v = \$null;
    }
    $s.= (' 'x$d)."S:$$v";
  }
  elsif (ref($v) eq 'ARRAY')
  {
    $s.= (' 'x$d)."A:(";

    my $c = '';
    my $x = 0;

    foreach my $a (map(strv($_,0),@{$v}))
    {
      $s.= "$c$x:$a";
      $c = ',';
      $x++;
    }
    $s.= ")";
  }
  elsif (ref($v) eq 'HASH')
  {
    $d++;
    $s.= "\n" if $s ne '';
    while( my ($k, $x) = each %{$v} ) {
      $s.= (' 'x$d)."H:".strv($k,$d+1).": ".strv($x,$d+1)."\n";
    }
    $s = substr($s, 0, -1);
  }
  elsif (ref($v))
  {
    $s.= ref($v);
  }
  $s.= (' 'x$d).'"'.$v.'"' if ref($v) eq '';
  return $s;
} # sub strv

Answer 9

为了记录，这里是几个实际解决方案的示例 你们使用 Data::Dumper。希望它可以帮助任何寻找简单子的人 用很少的努力漂亮地打印变量。谢谢大家！！

#!/usr/bin/perl -w
use strict;
use warnings;
use Data::Dumper;

my @myArray = qw ( a b c d e f g h i j k );

# Showing Difference between shift and pop and what happens to @myArray
my ($A, $B, $C, $D,);

$A = shift @myArray;
$B = pop   @myArray;
$C = shift @myArray;
$D = pop   @myArray;

# prtVar() usage is close to original desired simplicity 
# only needed to add the qw() 

prtVar(qw ($A $B $C $D));

sub prtVar
    {
    my (@vars) = @_;
    my $vname;

    foreach $vname (@vars)
        {
        print Data::Dumper->Dump([eval($vname)], [$vname]);
        }
    }

输出：

$A = 'a';
$B = 'k';
$C = 'b';
$D = 'j';