我怎么知道我可以调用具有特定签名的 Perl 6 方法？

Question

在 Perl 6（一种多分派语言）中，您可以找出是否存在与名称匹配的方法。如果有，您将获得与该名称匹配的 Method 对象列表：

class ParentClass {
    multi method foo (Str $s) { ... }
    }

class ChildClass is ParentClass {
    multi method foo (Int $n) { ... }
    multi method foo (Rat $r) { ... }
    }

my $object = ChildClass.new;

for $object.can( 'foo' )
    .flatmap( *.candidates )
    .unique -> $candidate {
    put join "\t",
        $candidate.package.^name,
        $candidate.name,
        $candidate.signature.perl;
    };


ParentClass foo :(ParentClass $: Str $s, *%_)
ChildClass  foo :(ChildClass $: Int $n, *%_)
ChildClass  foo :(ChildClass $: Rat $r, *%_)

这很好，但工作量很大。我宁愿有一些更简单的东西，例如：

 $object.can( 'foo', $signature );

我或许可以做很多工作来实现这一点，但我是否错过了一些已经存在的东西？

Answer 1

当我在这个问题上点击提交时，我有了这个想法，但这似乎仍然需要太多的工作。 cando 方法可以测试Capture（签名的逆）。我可以 grep 匹配的那些：

class ParentClass {
    multi method foo (Str $s) { ... }
    }

class ChildClass is ParentClass {
    multi method foo (Int $n) { ... }
    multi method foo (Rat $r) { ... }
    }

my $object = ChildClass.new;

# invocant is the first thing for method captures
my $capture = \( ChildClass, Str );

for $object.can( 'foo' )
    .flatmap( *.candidates )
    .grep( *.cando: $capture )
    -> $candidate {
    put join "\t",
        $candidate.package.^name,
        $candidate.name,
        $candidate.signature.perl;
    };

我不确定我是否喜欢这个答案。