带有方案的纯功能堆栈实现

Question

我想在方案中实现一个功能堆栈。 这是我的尝试：

(define make-stack
  (letrec ((do-op
            (lambda (stack op . val)
              (cond ((eq? op 'push)
                     (lambda (op . v)
                       (do-op (cons (car val) stack) op v)))
                    ((eq? op 'pop)
                     (lambda (op . v)
                       (do-op (cdr stack) op v)))
                    ((eq? op 'print)
                     (begin (display stack)
                            (newline)
                            (lambda (op . v)
                              (do-op stack op v))))))))
    (lambda (op . val)
      (do-op '() op val))))

堆栈可以像这个例子一样使用：

(define s make-stack)
((((((s 'push 1) 'push 2) 'push 3) 'print) 'pop) 'print)

这个例子的输出是：

((3) (2) (1))
((2) (1))

不完全是我想要的，但还不错。 我想问问这里有经验的策划者是否有办法让堆栈表现得更自然，例如这样：

(define s make-stack)
(s 'push 1)
(s 'push 2)
(s 'pop)
...

同时保持它的功能（所以没有可变性，没有set!）。

我想到的第一件事是继续返回一个不带参数的函数，但将每个 lambda (op . v) 更改为：

(lambda ()
  (lambda (op . v)
    ...

但这不起作用，因为我们仍然需要捕获返回的函数：

> (define s make-stack)
> ((s) 'push 1)
#<procedure>

Answer 1

正如 Amalloy 所建议的，功能性风格的原则与您的目标相反。然而，做一些类似的事情并非不可能 -

(define (run-stack s prgm)
  (foldl (lambda (step s) (apply s step))
         s
         prgm))

(run-stack
  make-stack
 '((push 1)
   (push 2)
   (push 3)
   (print)
   (pop)
   (print)))

为了测试这一点，我将make-stack 实现为 -

(define (dispatch-stack s)
  (lambda payload
    (match payload
      ((list 'pop)
       (dispatch-stack (cdr s)))
      ((list 'push v)
       (dispatch-stack (cons v s)))
      ((list 'print)
       (println (reverse s))
       (dispatch-stack s))
      (_ (error "invalid stack operation" payload)))))

(define make-stack
  (dispatch-stack null))

输出 -

'(1 2 3)
'(1 2)

我认为您希望看到的另一件事是Make a language in one hour: stacker。这将帮助您了解 Racket 等语言与您之前可能使用过的其他语言有何根本不同。

Answer 2

你的目标是矛盾的。如果s 是一个堆栈，并且您的操作纯粹是功能性的，那么(s 'push 1) 每次调用时都必须返回相同的内容。要捕捉变化的概念，您必须每次使用不同的s。这就是你的函数栈的工作方式：它给你一个新的栈，你必须用它来组合函数调用。