将地址处的值加载到寄存器中

Question

作为学习练习，我一直在进行手写汇编。我似乎无法弄清楚如何将地址的值加载到寄存器中。

在语义上，我想做以下事情：

_start:
        # read(0, buffer, 1)
        mov     $3, %eax            # System call 3 is read
        mov     $0, %ebx            # File handle 0 is stdin
        mov     $buffer, %ecx       # Buffer to write to
        mov     $1, %edx            # Length of buffer
        int     $0x80               # Invoke system call

        lea     (%ecx, %ecx), %edi  # Pull the value at address into %edi
        cmp     $97, %edi           # Compare to 'a'
        je      done

我已经用 C 编写了一个更高级别的实现：

char buffer[1];
int main()
{
    read(0, buffer, 1);
    char a = buffer[0];
    return (a == 'a') ? 1 : 0;
}

但是使用gcc -S 编译产生的程序集不能很好地移植到我上面的实现中。

我认为lea 是我应该用来将存储在%ecx 中的给定地址处的值加载到%edi 中的正确指令，但是在gdb 中检查时，%edi 在之后包含一个垃圾值该指令被执行。这种方法正确吗？

Answer 1

您需要的不是lea 指令，而是：

movzbl  (%ecx), %edi        

即零扩展到edi寄存器ecx中包含的内存地址处的字节。

_start:
        # read(0, buffer, 1)
        mov     $3, %eax            # System call 3 is read
        mov     $0, %ebx            # File handle 0 is stdin
        mov     $buffer, %ecx       # Buffer to write to
        mov     $1, %edx            # Length of buffer
        int     $0x80               # Invoke system call

        movzbl  (%ecx), %edi        # Pull the value at address ecx into edi
        cmp     $97, %edi           # Compare to 'a'
        je      done

---

一些建议

• 您实际上并不需要movz 指令：您不需要单独的加载操作，因为您可以将ecx 指向的内存中的字节直接与cmp 进行比较：

  cmpb $97, (%ecx)
  

• 您可能希望将要比较的字符（即'a'）指定为$'a' 而不是$97，以提高可读性：

  cmpb $'a', (%ecx)
  

• Avoiding conditional branches is usually a good idea。执行系统调用后，您可以立即使用以下代码使用cmov 来确定存储在eax 中的返回值，而不是执行条件跳转（即je 指令）：

  xor     %eax, %eax     # set eax to zero
  cmpb    $'a', (%ecx)   # compare to 'a'
  cmovz   %edx, %eax     # conditionally move edx(=1) into eax
  ret                    # eax is either 0 or 1 at this point
  

  edx 在系统调用之前被设置为1。因此，上述这种方法依赖于 edx 在整个系统调用中保留的事实（即 int 0x80 指令）。

• 更好的是，您可以在比较之后在al 上使用sete，而不是cmov：

  xor     %eax, %eax     # set eax to zero
  cmpb    $'a', (%ecx)   # compare to 'a'
  sete    %al            # conditionally set al
  ret                    # eax is either 0 or 1 at this point
  

  如果ZF 标志由cmp 设置（即，如果@ 指向的字节，则通过xor %eax, %eax 设置为零的寄存器al 将设置为1 987654353@ 是'a')。使用这种方法，您无需考虑系统调用是否保留edx，因为结果不依赖于edx。