搜索和删除临时文件/文件夹（脚本失败）

Question

我使用此脚本为所有用户清理历史记录、cookie 和缓存（临时 Internet 文件），它还应该清理临时目录，但似乎有问题。

我认为有两件事混淆了，%temp% 变量（= 我的环境中的 D:\TEMP） 以及%userprofile% 中的用户临时目录。

:: Works on Win XP  -and-  on Win 7

@echo off

Set "RegKey=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
set "regkey2=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\shell folders"

call:getspecialfolders "Cache, History, Cookies"

For /f "tokens=*" %%? in (
 'Reg.exe QUERY "%RegKey%" ^|findstr /ric:"\S-1-5-21-[0-9]*-[0-9]*-[0-9]*-[0-9]*$"'
 ) do (
 For /f "tokens=2,*" %%A in (
 'Reg.exe QUERY "%%?" /v ProfileImagePath ^|find /i "ProfileImagePath"'
 ) do call:Go %%B
)

start ""/w "%windir%\system32\RunDll32.exe" InetCpl.cpl,ClearMyTracksByProcess 255

:end ***


goto:EOF
:Go
   call Set "Target=%*"
   If EXIST "%Target%" call:Clear "%Target%"
exit /b 0

:Clear
REM echo.&echo.%~1\%$$Cache%
   pushD "%~1\%$$Cache%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_TEMP_IE.txt

REM echo.&echo.%~1\%$$History%\History.IE5
REM    pushD "%~1\%$$History%\History.IE5" &&(
REM    rmdir /S /Q .
REM    popD)2>C:\test1_History_IE.txt

REM echo.&echo.%~1\%$$History%
   pushD "%~1\%$$History%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_History.txt

REM echo.&echo.%~1\%$$Cookies%
   pushD "%~1\%$$Cookies%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_Cookies.txt

ECHO.&echo.%~1\%$$temp%
   pushD "%~1\%$$temp%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_Temp.txt
exit /b 0

:getspecialfolders
   Set "FoldersToClear=%~1"

   For %%* in (%FoldersToClear%) Do (
     For /f "tokens=2,*" %%A in (
     'reg.exe query "%regkey2%" /v %%* ^|find /i "%%~*"'
     ) do Call:sf1 "%%~B" "%%~*"
   )
   Call:sf2 "%temp%" "temp" "%userprofile%"
exit /b 0

:sf1
   Call set "sf=%~1"
   Call set "$$%~2=%%sf:%userprofile%\=%%"
exit /b 0

:sf2
   Call set "sf=%~1"
   call Set "usr=%~dpns3"
   Call set "$$%~2=%%sf:%usr%\=%%"
exit /b 0

但不知何故，我无法让最后一个“临时部分”发挥作用，因此它会清理 %temp%（我的环境中的 D:\Temp），并在 %userprofile% 中找到所有“临时目录”。

ie. 例如，这适用于 %temp%：

PushD "%Temp%" && (
ATTRIB -S -H -R -A /D /S & (
For /f "Tokens=*" %%* in ('dir "%Temp%" /B') Do (
RD "%Temp%\%%*" /S /Q || Del /F /S /Q "%Temp%\%%*"))&PopD)2>c:\test0b_TEMP.txt

这就是。为“用户临时”工作：

::Set Search directory to "Documents and Settings" folder
(Set Target=%AllUsersProfile:~0,-10%)

title,Finding the Temp subfolders in %Target%&COLOR 9E

If EXIST "%Target%",(
  For /f "Tokens=*" %%* in ('dir "%Target%" /B') Do (
   cd/D "%target%\%%*\Local Settings\Temp" && (
   ATTRIB -S -H -R -A /D /S >nul & (
  For /f "Tokens=*" %%* in ('dir /B') Do (
   RD "%%*" /S /Q ||Del /F "%%*" )))>nul)
 )

我希望有人可以帮助我修复脚本，我认为它在 :sf2 和/或与 %temp% 部分结合使用，现在有两件事混淆了（“用户临时”和“环境温度”）。

Answer 1

好吧，这次我认为有一种方法可以解决这个问题，即在进行清理之前直接添加一个检查变量是否包含相对路径或绝对路径。这个想法是测试字符串中是否存在冒号 (:)。如果存在冒号，则该路径之前无法转换为相对路径，因此应按原样使用，而不预先挂起配置文件路径，否则应在继续之前附加配置文件路径。

这是一个基本示例，您可以根据需要进行测试和使用：

@ECHO OFF
SET somepath=D:\TEMP
CALL :checkpath
SET "somepath=Local Settings\Temp"
CALL :checkpath
PAUSE
GOTO :EOF

:checkpath
IF "%somepath%"=="%somepath:*:=%" (ECHO Relative path) ELSE ECHO (Absolute path)

在您的特定情况下，我可能会应用这样的方法：

而不是

…
ECHO.&echo.%~1\%$$temp%
   pushD "%~1\%$$temp%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_Temp.txt
…

我会试试的

…
IF "%$$temp%"=="%$$temp:*:=%" (SET "tmppath=%~1\%$$temp%") ELSE SET "tmppath=%$$temp%"
ECHO.&echo.%tmppath%
   pushD "%tmppath%" &&(
   rmdir /S /Q .
   popD)2>C:\test1_Temp.txt
…

如您所见，一个临时变量用于存储要处理的实际路径。我知道只替换正在清除临时文件夹的部分就足够了，但是您可以看到，如果需要，该方法也可以轻松应用于其他文件夹。

Answer 2

您的 sf2 子例程似乎正试图通过切断路径的开头来获取 Temp 文件夹的相对路径，该路径本质上是用户配置文件路径：

Call set "$$%~2=%%sf:%usr%\=%%"

其中sf 包含临时文件夹，usr 包含用户配置文件。因此，例如，C:\Documents and Settings\APOC\Local Settings\Temp 而不是 Local Settings\Temp。

但是有一个问题。虽然sf 变量分配了正确的路径，但另一方面，usr 变量由于某种原因被分配了用户配置文件路径的短命名变量。也就是说，它接收的不是C:\Documents and Settings\APOC 之类的东西，而是C:\DOCUME~1\APOC 之类的东西。这是有问题的行：

call Set "usr=%~dpns3"

因此，当执行之前引用的行时，预期的替换永远不会发生，因为C:\Documents and Settings\APOC 与C:\DOCUME~1\APOC 不匹配，自然。结果，$$temp 变量以完整路径而不是相对路径结束，因此，引用 $$temp 的代码的相关部分无法按预期工作。

简而言之，我认为您根本不需要 sf2 例程。 sf1 例程似乎与sf2 一样，只是传递了一组不同的参数。所以，而不是

Call:sf2 "%temp%" "temp" "%userprofile%"

我建议你试试这个：

Call:sf1 "%temp%" "temp"

Answer 3

我稍微改变了 temp 的行，这是正确的方法吗？ （它确实有效，但格式是否正确？）

IF "%$$temp%"=="%$$temp:*:=%" (SET "tmppath=%~1\%$$temp%") ELSE SET "tmppath=%$$temp%"
ECHO.&echo.%tmppath%
   pushD "%tmppath%" &&(
   ATTRIB -S -H -R -A /D /S & (
   rmdir /S /Q . || Del /F /S /Q .
   )&popD)2>C:\test1_Temp.txt

+额外的“Del /f /s /q”用于可能的硬/只读文件（和附加属性）

顺便说一句 在带有“temp”部分的脚本中似乎仍然没有 100% 运行，我将 Windows 中的默认临时设置更改为用于测试目的的默认路径，我收到以下 3 个错误： screenshot of the error |网址：http://img199.imageshack.us/img199/9127/errorif.jpg

使用 Windows 默认临时路径运行的脚本：

[user] %UserProfile%\Local Settings\Temp and [system] %SystemRoot%\Temp

我不确定为什么会出现这些错误，当我将两个临时参数都设置为 D:\TEMP 时，我得到 3 倍于相同类型的错误，但比 D:\TEMP 而不是可用/活动用户 \local设置\温度。也许问题出在当地人〜1？？？ （虽然临时目录确实被清理了，但为什么它说它找不到路径？）