查找过去一小时内修改的文件的最简单方法是什么？

Question

这个问题是一个特例 “在 perl 中，查找在给定时间间隔内修改的文件的最简单方法是什么？” 并且下面的解决方案可以很容易地推广。 在 bash 中，我们可以输入

> find . -mtime -1h

但我想在纯 perl 中执行此操作。下面的代码就是这样做的。它在每个文件上显式运行stat。

有没有什么方法可以让它变得更简单或更优雅？当然，这比 bash 命令慢。我并不是想与 bash 竞争效率。我只是想纯粹用 perl 来做。

#!/usr/bin/env perl 
use strict; use warnings;
use File::Find;
my $invocation_seconds=time;
my $interval_left =  $invocation_seconds - (60 * 60); # one hour ago
my $count_all=0;
my @selected;
find(
    sub
    {
        $count_all++;
        my $mtime_seconds=(stat($_))[9];
        return unless defined $mtime_seconds; # if we edit files while running current script, this can be undef on occasion 
        return unless ($mtime_seconds>$interval_left);
        push@selected,$File::Find::name;
    }
    ,
    '.', # current directory 
);
my $end_seconds=time;
my $totalselected=scalar@selected;
print ($_,"\n",)for@selected;
print $^V; print " <- perl version\n";
print 'selected ',$totalselected, '/',$count_all,' in ',($end_seconds-$invocation_seconds),' seconds',"\n";

Answer 1

use File::Find::Rule qw( );

my $cutoff = time - 60*60;

say for File::Find::Rule->mtime( ">=$cutoff" )->in( "." );

Answer 2

以下演示示例代码利用函数stat 过滤掉最近一小时修改过的文件。

注意：代码稍作修改即可采用递归方式

use strict;
use warnings;
use feature 'say';

use constant STAMP => time() - 60*60;
use constant MTIME => 9;

my $dir = shift || '.';
my @files;

(stat($_))[MTIME] > STAMP && push @files, $_
    for glob("$dir/*");

say "
Files changes in last hour
--------------------------";
say for @files;

报告查找时间的递归版本

use strict;
use warnings;
use feature 'say';

use Time::HiRes qw(gettimeofday tv_interval);

use constant STAMP => time() - 60*60;
use constant MTIME => 9;

my $dir   = shift || '.';

my $start = [gettimeofday];
my $found = lookup($dir);
my $elapsed = tv_interval($start)

say "
Elapsed lookup time: $elapsed seconds";

say "
Files changed in last hour
--------------------------";
say for @$found;

exit 0;

sub lookup {
    my $dir  = shift;
    my $files;

    for my $item ( glob("$dir/*") ) {
        if( -d $item ) {
            my $matched = lookup($item);
            push @$files, $_ for @{$matched};
        }
        next unless (stat($item))[MTIME] > STAMP;
        push @$files, $item if -f $item;
    }

    return $files;
}