闭包内带有 OO 调用的静态本地调度表

【问题标题】：Static local dispatch table with OO calls within closures闭包内带有 OO 调用的静态本地调度表
【发布时间】：2013-10-01 06:25:47
【问题描述】：

我有一个调度表，我希望只初始化一次，并且只打算由一个函数使用。我希望将调度表移到子例程之外并移到同一个匿名块中，但是由于调度表使用闭包来调用传递给函数的对象的方法，因此将表移到函数之外会将其与对对象的访问分开.对于这个调度表，我还有哪些其他选择？

我使用的是 Perl 5.8，所以很遗憾我无法使用 state 变量。

sub foo {
  my ($self, $var) = @_;

  my %funcs = (
    a => sub { $self->_a() },
    b => sub { $self->_b() },
    ...
  );

  return $funcs{$var}->();
}

【问题讨论】：

我在示例中看到的唯一闭包是在匿名潜艇中的 $self 之上——真实代码中还有其他闭包吗？如果是这样，请添加一个示例。

标签： perl perl5.8

【解决方案1】：

调度表中的函数是$self 上的闭包。如果您将$self 作为参数传入，则可以解决这个问题。请注意，state 变量不是 $self 上的真正闭包，并且还需要显式参数。

my %funcs = (
  a => sub { shift->_a },  # these are like anonymous methods
  b => sub { shift->_b },
);

sub foo {
  my ($self, $var) = @_;
  my $meth = $funcs{$var} || die "There is no entry $var";
  return $self->$meth();   # sugary syntax
}

以下是为什么state 是个坏主意的演示：

use 5.010;
package Foo;
sub new { my ($c, $v) = @_; bless \$v, $c }

sub foo {
  my ($self) = @_;
  state $cb = sub { say $$self };
  $cb->();
}

Foo->new($_)->foo for 1..3;

输出：

1
1
1

inner sub 是一个闭包，但是$cb 的初始化只执行了一次。因此关闭的$self 是第一个。

【讨论】：

感谢您的解释！