在不激活的情况下设置放大 PowerPoint 文档窗口

Question

我正在从 Excel-VBA 文件创建 PPT，并希望将 ppt 的缩放设置为 100%。

如何在不激活 PowerPoint 窗口的情况下从 Excel 文件执行此操作？
或者我怎么能通过激活窗口来做到这一点？

以下excel中的示例代码在桌面上打开一个ppt文件并尝试设置此ppt的缩放但似乎不起作用：

Sub CreatePptAndSetZoom()
    Dim ppApp As PowerPoint.Application
    Dim ppPres As PowerPoint.Presentation
    Dim strTemplate$

    'Look for existing instance of PPT
    On Error Resume Next
    Set ppApp = GetObject(, "PowerPoint.Application")
    On Error GoTo 0

    'Create new instance of PPT if no instance exists
    If ppApp Is Nothing Then Set ppApp = New PowerPoint.Application

    'Define Path of Template and open new ppt
    strTemplate = Environ("UserProfile") & "\Desktop\Test.pptx"
    Set ppPres = ppApp.presentations.Open(strTemplate, False, True, True)

    'Set Zoom
    ppApp.ActiveWindow.View.Zoom = 100

End Sub

在 Excel 文件中设置来自 Excel 文件的缩放使用稍有不同的语句（不带 View）：

Application.ActiveWindow.Zoom = 100

有没有人知道如何在没有ppt文件中的任何代码的情况下解决这个问题？

Answer 1

在一些帮助下（感谢 R3uK！）我根据问题中的最后一个代码找到了以下解决方案：

解决方案：

使用以下内容代替 ppApp.ActiveWindow.View.Zoom = 100：

ppPres.Windows(1).Panes(2).Activate --> 激活主滑动窗格
ppPres.Windows(1).View.Zoom = 100 --> 设置活动窗格在窗口中的缩放比例


一些备注：强>

ppPres.Windows(1) -> 仅包含演示文稿的窗口的集合

ppApp.Windows(1) -> 包含所有打开的 ppt 窗口的集合。因此，如果在第 1 项之前打开 ppt，则不会返回正确的窗口。

ppPres.Windows(1).Panes(2) -> ppt 窗口内的窗格集合，在我的情况下，这些窗格是依赖于项目编号的以下 ViewType：

第 1 项：ppViewThumbnails（左侧的微型幻灯片）
第 2 项：ppViewSlide（主视图）
第 3 项：ppViewNotesPage（底部评论区）

所以在我的示例中，我想更改主幻灯片视图窗格中第 2 项的缩放。

Answer 2

您的代码使用延迟出价可以顺利运行：

Sub ZoomInPptFromExcel()
    Dim ppApp As Object

    'Get existing instance of PPT
    On Error Resume Next
    Set ppApp = GetObject(, "PowerPoint.Application")
    On Error GoTo 0

    'Set Zoom
    ppApp.ActiveWindow.View.Zoom = 100

End Sub

---

Sub CreatePptAndSetZoom()
    Dim ppApp As Object 'PowerPoint.Application
    Dim ppPres As Object 'PowerPoint.Presentation
    Dim strTemplate$

    'Look for existing instance of PPT
    On Error Resume Next
    Set ppApp = GetObject(, "PowerPoint.Application")
    On Error GoTo 0

    'Create new instance of PPT if no instance exists
    If ppApp Is Nothing Then Set ppApp = CreateObject("PowerPoint.Application")

    'Define Path of Template and open new ppt
    strTemplate = Environ("UserProfile") & "\Desktop\Test.pptx"
    Set ppPres = ppApp.Presentations.Open(strTemplate, False, True, True)
    'Set ppPres = ppApp.Presentations.Add

    'Set Zoom
    ppApp.ActiveWindow.View.Zoom = 100
End Sub