VB.NET 中的 C 函数

Question

我在从 DLL 调用 C 函数时遇到了一些问题，希望有人能帮助我。该函数返回 -101，它转换为“错误参数”。我传递的值是从另一个成功的函数调用返回的，所以我目前的假设是我错误地构建了结构。任何帮助表示赞赏。

函数定义为：

int sm_switch_channel_input(struct sm_switch_channel_parms *switchp) 

Parameters
*switchp (a structure of the following type): 
typedef struct sm_switch_channel_parms {
     tSMChannelId channel;     /* in */
     tSM_INT st;      /* in */
     tSM_INT ts;      /* in */
     enum kSMTimeslotType type;    /* in */
} SM_SWITCH_CHANNEL_PARMS;

typedef struct tSMChannelId_struct *tSMChannelId;
typedef int tSM_INT;
enum kSMTimeslotType {
 kSMTimeslotTypeALaw,
 kSMTimeslotTypeMuLaw,
 kSMTimeslotTypeData,
};

这就是我定义和称呼它的方式...

Enum kSMTimeslotType
    kSMTimeslotTypeALaw = 0
    kSMTimeslotTypeMuLaw = 1
    kSMTimeslotTypeData = 2
End Enum
Public Structure sm_switch_channel_input_params
    <MarshalAsAttribute(UnmanagedType.SysInt)> _
    Public channel As IntPtr
    <MarshalAsAttribute(UnmanagedType.I4)> _
    Public stream As Integer
    <MarshalAsAttribute(UnmanagedType.I4)> _
    Public timeslot As Integer
    <MarshalAsAttribute(UnmanagedType.U4)> _
    Public tsType As kSMTimeslotType
End Structure

<DllImport("TiNG.dll")> _
Private Shared Function sm_switch_channel_input_iPsCtiie1_3__(ByRef x As sm_switch_channel_input_params) As Integer
End Function

Dim sscip As sm_switch_channel_input_params
Dim err as Integer

sscip.channel = chanA
sscip.stream = streamA
sscip.timeslot = timeSlotA
sscip.tsType = kSMTimeslotType.kSMTimeslotTypeMuLaw
err = sm_switch_channel_input_iPsCtiie1_3__(sscip)

Answer 1

我认为 SysInt 属性是导致您的问题的原因。在这种情况下没有必要，因为IntPtr 将始终根据当前平台正确编组。您还缺少 StructLayout 属性

还有一些其他属性也不是必需的。我会尝试使用以下定义

Enum kSMTimeslotType
    kSMTimeslotTypeALaw = 0
    kSMTimeslotTypeMuLaw = 1
    kSMTimeslotTypeData = 2
End Enum

<StructLayout(LayoutKind.Sequential)> _
Public Structure sm_switch_channel_input_params
    Public channel As IntPtr
    Public stream As Integer
    Public timeslot As Integer
    Public tsType As kSMTimeslotType
End Structure

Answer 2

从您的 VB 代码中的函数名称来看，它是一个 C++ 函数，并按原样导出。因此，它不使用“stdcall”调用约定（P/Invoke 默认采用该约定），而是使用"thiscall"（VC++ 用于所有非可变参数 C++ 函数）。所以试试这个：

<DllImport("TiNG.dll", CallingConvention := CallingConvention.ThisCall)> _
Private Shared Function sm_switch_channel_input_iPsCtiie1_3__ ...

解决这个问题的更合适的方法是在 C 代码中使用 extern "C" 和 __stdcall 来装饰函数：

extern "C" {
    int __stdcall sm_switch_channel_input(struct sm_switch_channel_parms *switchp) 
    ...
}

那么您的原始 P/Invoke 声明应该可以正常工作。

附带说明，您的所有 MarshalAs 属性都是多余的（它们指定的行为已经是您应用它的类型的默认行为），因此您可以完全删除它们。