Excel VBA中mac的睡眠等效项答案

【问题标题】：Sleep Equivalent for mac in Excel VBAExcel VBA中mac的睡眠等效项
【发布时间】：2021-09-12 13:41:49
【问题描述】：

我想在 Excel 的 macOS VBA 编辑器中添加一个 500 毫秒的等待块。我知道

Application.Wait (Now + TimeValue("0:00:01"))

有效，但这不能低于 1 秒。我也试过 sleep 命令：

Public Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As LongPtr)
...
Sleep 500

但这给了我一个错误提示

File Not Found "kernel32"

有什么方法可以做到这一点？

【问题讨论】：

Cross Compatibility of Millisecond Timer Resolution in Excel VBA 有帮助吗？
据我了解，它确实概述了一种计算代码执行时间的方法，但我想为我的代码添加 500 毫秒的轻微延迟，而不是计算需要多长时间。如有错误请指正，谢谢！
我不熟悉在 Mac 上使用 Excel，但AppleScript “delay” command not working since switch to Yosemite 的一些答案看起来很有用。

标签： excel vba macos

【解决方案1】：

这适用于 Windows 和 Mac：

Option Explicit

#If Mac Then
    #If VBA7 Then
        Public Declare PtrSafe Sub USleep Lib "/usr/lib/libc.dylib" Alias "usleep" (ByVal dwMicroseconds As Long)
    #Else
        Public Declare Sub USleep Lib "/usr/lib/libc.dylib" Alias "usleep" (ByVal dwMicroseconds As Long)
    #End If
#Else 'Windows
    #If VBA7 Then
        Private Declare PtrSafe Sub MSleep Lib "kernel32" Alias "Sleep" (ByVal dwMilliseconds As Long)
    #Else
        Private Declare  Sub MSleep Lib "kernel32" Alias "Sleep" (ByVal dwMilliseconds As Long)
    #End If
#End If

Public Sub Sleep(ByVal dwMilliseconds As Long)
#If Mac Then
    USleep dwMilliseconds * 1000&
#Else
    MSleep dwMilliseconds
#End If
End Sub

【讨论】：

【解决方案2】：

您上面的代码块只需添加一点点即可工作。只需将 TimeValue 除以 2 即可得到 500 毫秒

Application.Wait (Now + TimeValue("0:00:01") / 2)

【讨论】：