如果尚未打开，则打开工作簿，如果已经打开，则获取该参考

Question

我有一个场景可以在另一个工作簿路径中的工作簿中进行一些更改。但问题是我需要检查工作簿是否已经打开。如果不是，我需要将打开的实例添加到工作簿变量中。

这是我用来检查工作簿是否打开的代码，然后是打开代码

Function IsFileOpen(fileFullName As String)
    Dim FileNumber As Integer
    Dim errorNum As Integer

    On Error Resume Next
    FileNumber = FreeFile()   ' Assign a free file number.
    ' Attempt to open the file and lock it.
    Open fileFullName For Input Lock Read As #FileNumber
    Close FileNumber       ' Close the file.
    errorNum = Err         ' Assign the Error Number which occured
    On Error GoTo 0        ' Turn error checking on.
    ' Now Check and see which error occurred and based
    ' on that you can decide whether file is already
    ' open
    Select Case errorNum
        ' No error occurred so ErroNum is Zero (0)
        ' File is NOT already open by another user.
        Case 0
         IsFileOpen = False

        ' Error number for "Permission Denied." is 70
        ' File is already opened by another user.
        Case 70
            IsFileOpen = True

        ' For any other Error occurred
        Case Else
            Error errorNum
    End Select

End Function
Public Function getConsolidatedDataFile() As Workbook
    Dim p As String
    p = ActiveWorkbook.Path
    Dim cf As String
    cf = printf("{0}\ConsolidatedData.xlsx", p)
    Dim wb As Workbook
    Dim fo As Boolean
    fo = IsFileOpen(cf)
    If fo = False Then wb = Workbooks.Open(filename:=cf)
    ''I need to get the code for this place of fo is true
    getConsolidatedDataFile wb

End Function

因此，如果文件打开，我需要将该工作簿放入该 wb 变量中。

Answer 1

我有办法

If fo = False Then
    Set wb = Workbooks.Open(filename:=cf)
Else
    Dim w As Workbook
    For Each w In Workbooks
        If w.FullName = cf Then
            Set wb = w
        End If
    Next
End If

在循环中，它遍历所有工作簿，如果它在那里获取该引用..

Answer 2

希望对你有帮助

Dim dict As Dictionary

Function OpenFile(fileFullName As String) As Workbook


If (dict.Exists(fileFullName)) Then

OpenFile = dict.Item(fileFullName)

End If

dict.Add "fileFullName", Workbooks.Open(Filename:=fileFullName)

OpenFile = dict.Item(fileFullName)

End Function

Application.ActiveWorkbook = OpenFile(fileFullName)

Answer 3

要将工作簿引用到应该打开的工作簿集合 -

Workbook 对象是 Workbooks 集合的成员。 Workbooks 集合包含当前在 Microsoft Excel 中打开的所有 Workbook 对象。

MSDN Wrokbook Object

因此，如果您的工作簿位于同一个 Excel 实例中，请尝试如下：

Public Sub TestMe()        
    Dim wb As Workbook
    Set wb = Workbooks("12.xlsx")    
End Sub

如果不在同一个实例中，那么GetObject 应该可以工作：

Public Sub TestMe()        
    Dim wb As Workbook
    Set wb = GetObject("C:\path\12.xlsx")    
    Debug.Print wb.Worksheets(1).Name
End Sub

GetObject MSDN

---

这是同一实例中的 3 个工作簿的外观：

这是 2 个工作簿在 2 个不同实例中的样子：

使用多个实例的优缺点 (Source answers.microsoft.com)：

优点

• 如果您有 32 位 Excel，则每个实例最多可使用 3 GB 内存。如果您有一台功能强大的计算机、非常重的文件和 32 位 Excel，则每个 Excel 实例可以使用 3 GB。因此，例如Excel.exe 的 2 个实例，可以说 Excel 的总内存可以使用三元组。 （请注意，64 位 Excel 不需要这样做，因为它不受每个实例 3 GB 内存的限制）

• 如果你想有一个单独的 Undo 链，让每个 Undo 只在当前活动的工作簿中撤消，那么单独的实例确实可以实现这一点。

缺点

• 如果您希望所有打开的文件共享一个公共 Undo 链，那么使用多个实例将无法实现。

• 如果您希望能够例如按 Ctrl+F6 在打开的文件之间快速跳转，然后使用多个实例将无法实现。

• Paste Special 在实例之间不起作用。有关详细信息，请参阅此内容。

• 无法通过单击在单独运行的实例中的 2 个文件之间建立工作簿链接，并且不会实时更新。

---

代码看起来没问题，只需使用Set 关键字：

If fo = False Then set wb = Workbooks.Open(filename:=cf)

Answer 4

这是一个快速功能，如果工作簿尚未打开，它将打开它：

Function GetWorkBook(ByVal sFullName As String, Optional ReadOnly As Boolean) As Workbook
    Dim sFile As String: sFile = Dir(sFullName)
    On Error Resume Next
        Set GetWorkBook = Workbooks(sFile)
        If GetWorkBook Is Nothing Then Set GetWorkBook = Workbooks.Open(sFullName, ReadOnly:=ReadOnly)
    On Error GoTo 0
End Function