从 regedit 获取 InstallDir - CMD/批处理文件

Question

这是我的批处理代码：

@echo off
title Program
cd C:\Program Files (x86)\Company\Program
start xxxx.exe
exit

我的问题是......如果我不知道程序安装在哪里，我如何找到这部分：C:\Program Files (x86)\Company\Program 和批处理文件？我需要从 regedit 中的 InstallDir 获取安装路径。有可能吗？

我需要这样做：

@echo off
title Program
*here get program path from InstallDir in regedit*
start xxxx.exe
exit

-

Regedit 路径：Software\Company\Program - 这里我得到 InstallDir REG_SZ 值和程序路径（C:\Program Files (x86)\Company\Program）。 p>

Answer 1

试试这个，在第 3 行更改 Company\Program 之后：

@Echo Off
For /F "Skip=1 Tokens=2*" %%A In (
    'Reg Query "HKLM\SOFTWARE\Company\Program"^
    /V "InstallDir" 2^>Nul'
) Do Set "EP=%%~B"

Echo %%EP%%=%EP%&Pause

您的路径将保存在变量%EP% 中，为了演示目的，我在最后一行中有Echo'd。您可能需要将该行替换为：

Start "" /D "%EP%" "executable.ext"

或者

Start "" "%EP%\executable.ext"

编辑

如果您尝试卸载注册表项，它可能会更适合您。举个例子：

@Echo Off
For /F "Skip=1 Tokens=2*" %%A In (
    'Reg Query "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\U‌​ninstall\Company\Program"^
    /V "UninstallString" 2^>Nul'
) Do Start "" "%%~B"

Answer 2

好的。我创建了这个：

@echo off
:CheckOS
IF EXIST "%PROGRAMFILES(X86)%" (GOTO 64BIT) ELSE (GOTO 32BIT)

:64BIT
FOR /F "Skip=2 tokens=2*" %%A IN (
   'REG QUERY "HKLM\Software\Wow6432Node\Electronic Arts\NFSMW" /v InstallDir'
) DO (set cdNFSMW=%%B)

GOTO END

:32BIT
FOR /F "Skip=2 tokens=2*" %%A IN (
   'REG QUERY "HKLM\Software\Electronic Arts\NFSMW" /v InstallDir'
) DO (set cdNFSMW=%%B)

GOTO END

:END

chdir /d %cdNFSMW%
start unins000.txt
exit

而且效果很好。但是，不知道哪种方式更好更准确？

这个：

@echo OFF

reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && set OS=32BIT || set OS=64BIT

if %OS%==32BIT echo This is a 32bit operating system
if %OS%==64BIT echo This is a 64bit operating system

或者这个：

:CheckOS
IF EXIST "%PROGRAMFILES(X86)%" (GOTO 64BIT) ELSE (GOTO 32BIT)

:64BIT
echo 64-bit...
GOTO END

:32BIT
echo 32-bit...
GOTO END

:END

你怎么看？哦...还有一件事 - "skip=2" 的值是多少？

重要吗？写的好吗？