在 delphi 中使用 Tregistry 类将 reg_binary 读取为字符串

Question

我正在尝试将 reg_binary 作为字符串从注册表项中获取。

这是我的功能

function ReadBinString(key: string; AttrName: string): string;
var
 ReadStr: TRegistry;

begin
// Result := '';
ReadStr := TRegistry.Create(KEY_WRITE OR KEY_WOW64_64KEY);
ReadStr.RootKey := HKEY_LOCAL_MACHINE;

   if ReadStr.OpenKey(key, true) then
begin

  Result := ReadStr.GetDataAsString(AttrName);
end;

ReadStr.CloseKey;
ReadStr.Free;
end;

这是我的注册表项导出：

 Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\ZES\ACINFO]
"iamthere"=dword:00000001
"ArrayOrder"=hex:4d,79,45,78,63,6c,75,64,65

问题是，函数返回空字符串

我什至尝试以管理员身份运行以确保它不是权限。

有什么帮助吗？

Answer 1

扩展我对该问题的评论，我会使用如下代码：

function ReadBinString(RootKey: HKEY; Access: LongWord; const KeyName,
  ValueName: string; Encoding: TEncoding): string;
var
  Registry: TRegistry;
  Bytes: TBytes;
begin
  Registry := TRegistry.Create(Access);
  try
    Registry.RootKey := RootKey;
    if Registry.OpenKeyReadOnly(KeyName) then begin
      SetLength(Bytes, Registry.GetDataSize(ValueName));
      Registry.ReadBinaryData(ValueName, Pointer(Bytes)^, Length(Bytes));
      Result := Encoding.GetString(Bytes);
    end else begin
      Result := '';
    end;
  finally
    Registry.Free;
  end;
end;

对于您的数据，您可以这样称呼它：

Value := ReadBinString(HKEY_LOCAL_MACHINE, KEY_WOW64_64KEY, 'Software\ZES\ACINFO', 
  'ArrayOrder', TEncoding.ANSI);

注意事项：

• 我避免对根密钥进行硬编码。
• 我使用TEncoding 将字节数组解码为文本。这比GetDataAsString 有效得多。
• 我已允许调用者指定要使用的编码。
• 我已允许调用者指定访问标志。
• 我使用了OpenKeyReadOnly，因为我们不需要写权限。

Answer 2

感谢 David Heffernan，我提出了这个解决方案：

function ReadBinString(key: string; AttrName: string): string;
var
ReadStr: TRegistry;
hexStr : string;
I : Integer;
begin
// Result := '';
 ReadStr := TRegistry.Create(KEY_READ OR KEY_WOW64_64KEY);
 ReadStr.RootKey := HKEY_LOCAL_MACHINE;

 if ReadStr.OpenKey(key, true) then
 begin

hexStr := ReadStr.GetDataAsString(AttrName);

hexStr := hexStr.Replace(',','');
for I := 1 to length (hexStr) div 2 do
Result:= Result+Char(StrToInt('$'+Copy(hexStr,(I-1)*2+1,2)));

end;

ReadStr.CloseKey;
ReadStr.Free;
end;

再次感谢 David Heffernan ...这对我有用：

    function ReadBinString(key: string; AttrName: string): string;
    var
      ReadStr: TRegistry;
      hexStr: string;
      I: Integer;
      Bytes: TBytes;
      Encoding: TEncoding;
    begin

      Encoding :=  TEncoding.ANSI;

      Result := '';
      ReadStr := TRegistry.Create(KEY_READ OR KEY_WOW64_64KEY);
      ReadStr.RootKey := HKEY_LOCAL_MACHINE;
      try

        if ReadStr.OpenKeyReadOnly(key ) then
        begin

          SetLength(Bytes, ReadStr.GetDataSize(AttrName));
          ReadStr.ReadBinaryData(AttrName, Pointer(Bytes)^, Length(Bytes));
          Result := Encoding.GetString(Bytes);

          // hexStr := ReadStr.GetDataAsString(AttrName);
          //
          // hexStr := hexStr.Replace(',','');
          // for I := 1 to length (hexStr) div 2 do
          // Result:= Result+Char(StrToInt('$'+Copy(hexStr,(I-1)*2+1,2)));

        end;

      except

      end;
      ReadStr.CloseKey;
      ReadStr.Free;
    end;