Applescript：将剪贴板文本粘贴到打开/保存对话框中

Question

我有许多未命名的 TextEdit 文件。我想使用 applescript 来保存每个文档的第一行文本作为名称。

以下将选择并复制文档的第一行（不优雅，但它有效），但我不知道如何将剪贴板粘贴到保存对话框中（然后点击“保存”）。有人可以帮忙吗？

tell application "TextEdit" to activate
tell application "TextEdit"

tell application "System Events" to key code 126 using command down
tell application "System Events" to key code 125 using shift down
tell application "System Events" to key code 8 using command down


end tell

Answer 1

有两种方法：

1) 使用 GUI 脚本的方法：这是您已经开始做的事情。您可以像用户一样模拟键盘事件。不推荐它主要有 3 个原因： 它通常很慢（您需要添加延迟以留出系统打开窗口的时间，关闭它们，..）。在脚本执行过程中，如果用户误按了键/鼠标，您的脚本将失败。最后，您几乎不依赖应用程序的用户界面：如果编辑器（此处为 Apple 与 TextEdit）更改了某些内容，例如快捷键，您的脚本将不再工作。

尽管如此，如果您仍想以这种方式使用，这里是为您执行此操作的脚本。我建议您像我一样添加 cmets（如何记住键码 8 是 'c' ！）。我添加了一些额外的选项来选择要保存的路径（转到主文件夹，输入特殊路径，...）。使用与否由您决定：

tell application "TextEdit"
activate
tell application "System Events"
    key code 126 using command down -- command up (cursor at start)
    key code 125 using shift down -- shift down (select 1st line)
    keystroke "c" using command down -- command C (copy)
    keystroke "s" using command down -- open save dialog
    delay 0.5 -- to let save as dialog time to open
    keystroke "v" using command down -- paste the title from clipboard

    -- other options
    -- keystroke "h" using {command down, shift down} -- go home directory
    delay 0.5
    keystroke "g" using {command down, shift down} -- go to dialog
    delay 0.5
    keystroke "Desktop/Sample" -- path from Documents folder to Sample folder on Desktop
    delay 0.5
    keystroke return -- close the go to dialog
    delay 0.5

    keystroke return -- close the save as dialog
end tell
end tell

2) 使用Applescript指令的方法。它通常更短，更优雅的脚本，运行速度更快，并且用户在执行过程中不能破坏它。下面的脚本与上面的脚本相同：它选择第一个文本行并使用该标题保存文档。第 1 行定义了保存的文件夹：

set myPath to (path to desktop folder) as string -- path where to save file
tell application "TextEdit"
activate
tell front document
    set myTitle to first paragraph
    set myTitle to text 1 thru -2 of myTitle -- to remove the return at end of paragraph
    save in (myPath & myTitle)
end tell
end tell

希望对你有帮助