在grep匹配中替换多次出现的字符

Question

我正在尝试使用 TextWrangler 获取一堆文本文件，匹配一些尖括号标签中的所有内容（到目前为止一切都很好），并且对于 每个 匹配，替换所有出现的特定与另一个角色。

例如，我想采取类似的东西

xx+xx <f>bar+bar+fo+bar+fe</f> yy+y <f>fee+bar</f> zz

匹配<f> 和</f> 中的所有内容，然后用* 替换所有+（但仅限“f”标签内）。

xx+xx <f>bar*bar*fo*bar*fe</f> yy+y <f>fee*bar</f> zz

我想我可以轻松地将包含 + 的“f”标签与类似的表达式匹配

<f>[^<]*\+[^<]*</f>

但我不知道如何为每个匹配项仅替换一个字符子类。我不知道每个标签中有多少个+。 我认为我应该为第一个正则表达式的所有匹配项运行一个正则表达式，但我不确定该怎么做。

（换句话说，我想匹配所有+，但只在特定的尖括号标签内）。

有人有提示吗？

非常感谢， 丹尼尔

Answer 1

如果您对 awk 解决方案感到满意：

$ awk '{
    while ( match($0,/<f>[^<]*\+[^<]*<\/f>/) ) {
        tgt = substr($0,RSTART,RLENGTH)
        gsub(/\+/,"*",tgt)
        $0 = substr($0,1,RSTART-1) tgt substr($0,RSTART+RLENGTH)
    }
    print
}' file
xx+xx <f>bar*bar*fo*bar*fe</f> yy+y <f>fee*bar</f> zz

以上内容可以在任何 UNIX 机器上的任何 shell 中使用任何 awk。它依赖于每个<f>...</f> 中没有<，如您的示例代码所示。如果可以将其包含在您的示例中，我们可以调整脚本来处理它：

$ awk '{
    gsub("</f>",RS)
    while ( match($0,/<f>[^\n]*\+[^\n]*\n/) ) {
        tgt = substr($0,RSTART,RLENGTH)
        gsub(/\+/,"*",tgt)
        $0 = substr($0,1,RSTART-1) tgt substr($0,RSTART+RLENGTH)
    }
    gsub(RS,"</f>")
    print
}' file
xx+xx <f>bar*bar*fo*bar*fe</f> yy+y <f>fee*bar</f> zz