在 Excel 中编写折线图

Question

我被赋予了以编程方式生成此图表的任务：

.

到目前为止，我已经找到了这些resources 和 MSDN Docs 使用 VBA 生成图表。

这是我当前的代码：

Private Sub CommandButton1_Click()
Sheet1.Select
ActiveSheet.Shapes.AddChart.Select
ActiveSheet.Shapes(1).Top = 10
ActiveSheet.Shapes(1).Left = 10
ActiveChart.ChartType = xlLineMarkers

ActiveChart.PlotArea.Select
ActiveChart.SetSourceData Source:=Range("Table1")
ActiveChart.HasTitle = True
ActiveChart.ChartTitle.Text = Sheet1.Range("B2").Value
End Sub

但是，我并没有完全得到我需要的输出。

这是一个示例数据表：

注意事项：

1. 橙色线 - 每个项目的上限和下限。
2. 蓝色虚线 - 每个项目的值。

Answer 1

好吧，接下来就接近了。您需要更改范围（或将其设置为动态找到它 - 这是另一个问题）并设置标题所在的单元格范围等，但我认为这应该可以帮助您：

Excel 2013 版：

ActiveSheet.Shapes.AddChart2(332, xlLineMarkers).Select
With ActiveChart

    ' Set the source
    .SetSourceData Source:=Range("Sheet1!$A$1:$D$6")

    ' Set the title
    .ChartTitle.Text = Sheet1.Range("B1").Value

    ' Format the labels to 45 degrees
    .Axes(xlCategory).TickLabels.Orientation = 45

    ' Set Line 2 to Orange dash, no marker
    With .FullSeriesCollection(2).Format.Line
        .ForeColor.ObjectThemeColor = msoThemeColorAccent2
        .DashStyle = msoLineDash
        .Parent.Parent.MarkerStyle = -4142
        'add other formatting here
    End With

    ' Set Line 3 to Orange dash, no marker
    With .FullSeriesCollection(3).Format.Line
        .ForeColor.ObjectThemeColor = msoThemeColorAccent2
        .DashStyle = msoLineDash
        .Parent.Parent.MarkerStyle = -4142
        'add other formatting here
    End With

End With

我通过录制一个宏然后添加一个With 来消除对.Activechart 的不必要使用。如果您以后需要参考它，您总是可以Set 它，但这又是另一个问题。如果您想进一步细化，还可以创建一个循环来取出 .FullSeriesCollection() 的一段代码。

Excel 2007/2010 版本：（具有循环和可见性解决方法以允许颜色更改）

ActiveSheet.Shapes.AddChart.Select
With ActiveChart
    .ApplyLayout (1)
    .SetSourceData Source:=Range("'Sheet1'!$A$1:$D$6")
    .ChartType = xlLineMarkers
    .Axes(xlCategory).TickLabels.Orientation = 45
    .ChartTitle.Text = Sheet1.Range("B1").Value

    For scoln = 2 To 3
        With .SeriesCollection(scoln)
            .Format.Line.Visible = False
            .Format.Line.Visible = True
            .Format.Line.ForeColor.RGB = 683236
            .Format.Line.DashStyle = msoLineSysDash
            .MarkerStyle = -4142
        End With
    Next

    With .SeriesCollection(1)
         .MarkerStyle = 8
         .MarkerSize = 8
     End With
End With