【问题标题】:Why does this Haskell filter terminate?为什么这个 Haskell 过滤器会终止?
【发布时间】:2012-10-29 22:09:44
【问题描述】:

我不明白为什么下面的 Haskell 代码会在 GHCi 下终止:

let thereExists f lst = (filter (==True) (map f lst)) /= []
thereExists (\x -> True) [1..]

考虑到它的第二个参数是无限的,我没想到对 filter 的调用会完成,而且我认为在完全计算 lhs 之前不会进行比较。发生了什么?

【问题讨论】:

  • 顺便说一句,thereExists 在标准库中,只不过它被称为any。
  • 我让学生写了他们自己版本的 thereExists 作为测试题。我告诉一位学生,他的版本(上图)没有终止,他告诉我确实终止了。他是对的,我现在明白为什么了。
  • 还要注意 [1..] 是 not 必须是无限的。默认类型为 [Integer],但也可以是 [Int],通常包含 2^31-1 或 2^63-1 个元素。

标签: haskell ghc lazy-evaluation ghci


【解决方案1】:

比较可以在 LHS 完全计算之前进行。只要filter 产生了一个元素,/= 就能够断定该列表不可能等于[],并立即返回True。

/= 在列表中的实现如下:

(/=) :: Eq a => [a] -> [a] -> Bool
[] /= []         = False
[] /= (y:ys)     = True
(x:xs) /= []     = True
(x:xs) /= (y:ys) = (x /= y) || (xs /= ys)

由于 Haskell 是惰性的,我们只会对参数进行评估,以选择我们将使用哪个右手边。对您的示例的评估如下所示:

    filter (== True) (map (\x -> True) [1..]) /= []
==> (True : (filter (== True) (map (\x -> True) [2..]))) /= []
==> True

只要我们知道/= 的第一个参数是(1 : something),它就会匹配上面代码中/= 的第三个等式,所以我们可以返回True。

但是,如果您尝试thereExists (\x -> False) [1..],它确实不会终止,因为在这种情况下,filter 将永远不会在生成我们可以匹配的构造函数方面取得任何进展。

     filter (== True) (map (\x -> False) [1..]) /= []
==>  filter (== True) (map (\x -> False) [2..]) /= []
==>  filter (== True) (map (\x -> False) [3..]) /= []
...

以此类推。

总之,无限列表上的thereExists 可以在有限时间内返回True,但绝不会返回False。

【讨论】:

  • 谢谢。你能告诉我这个魔法是如何实现的吗? /= 是内置在 Haskell 中的,还是可以用 Haskell 编写的?
  • @espertus 它可以用 Haskell 编写 - 确实如此。它定义为xs /= ys = not (xs == ys),(==) 由[] == [] = True; (x:xs) == (y:ys) = x == y && xs == ys; _ == _ = False 给出。
  • @espertus 这只是非严格的评估。这个案子没有什么特别之处。这就是 Haskell 的一般工作方式。
猜你喜欢
  • 1970-01-01
  • 2015-01-09
  • 2014-01-08
  • 2017-07-03
  • 1970-01-01
  • 1970-01-01
  • 2015-04-25
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多