vba - 使用具有“动态创建名称”的变量

Question

我希望你能帮助我提出一个疯狂的想法。我不确定这是否可能，我什至不知道如何称呼它。

我想使用一个变量来动态建立它的名字。

这可能吗？

我正在逐行读取一个 html 文件，我的代码需要知道在哪个工作表中存储当前行。 我有大约 10 张纸，但对于这个问题，我只会使用两张纸：Module 和 Switch。 对于每张工作表，我都有一个“WhateverSheetRow”变量来记录更新的行。在此示例中：ModuleRow 和 SwitchRow。 我的想法是，因为我在每张工作表的每一行中都写，我知道哪一行是最后更新的，所以在下一次出现时，我会将它增加 1 并更新它，而不是使用 find 或任何其他“最后空行”更新方法。 有没有办法将 WhatSheetRow 增加 1 以动态构建变量名？

Dim ModuleRow as Long
Dim SwitchRow as Long
Dim Found as String
If Found = "Module" Then             'String found is Module
Found & "Row" = Found & "Row" + 1    'Increase ModuleRow by one
Sheets(Found).Range("A" & (ModuleRow)).Value = "Y"

所以问题是是否有办法“构建”变量名并使用它。

或者什么是更好的选择？

非常感谢！

Answer 1

您可以在其他一些languages 中使用那个（坏的）想法，但不能在 VBA 中使用。使用数组或字典。如果您要更改脚本中工作表的数量或位置，请使用字典。

Option Explicit

Sub demo()

    Dim wb As Workbook, ws As Worksheet
    Set wb = ThisWorkbook
    
    ' using an array
    Dim arLastRow() As Long
    ReDim arLastRow(1 To wb.Sheets.Count)
    For Each ws In wb.Sheets
        arLastRow(ws.Index) = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    Next
    
    ' set found
    Dim Found As String
    Found = "Module" ' or Switch or any other sheet name
    With wb.Sheets(Found)
       arLastRow(.Index) = arLastRow(.Index) + 1
        .Cells(arLastRow(.Index), "A") = "Y"
    End With
    
    ' or using a dictionary
    Dim dictLastRow As Object
    Set dictLastRow = CreateObject("Scripting.Dictionary")
    For Each ws In wb.Sheets
        dictLastRow(ws.Name) = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    Next
       
    ' set found
    Found = "Switch" ' or Module or any other sheet name
    With wb.Sheets(Found)
        dictLastRow(.Name) = dictLastRow(.Name) + 1
        .Cells(dictLastRow(.Name), "A") = "Y"
    End With
End Sub