根据行值删除列

Question

我有一张包含数据的表格。我想根据行值删除列。

我的代码没有停止，当我点击转义时，它已经从我的起始列中删除了所有列。

我想检查第 2 行中从 D 列到最后使用的列（我现在大约有 100 列）中的值，如果它们包含 C15、C17 等，则不要执行任何操作，否则，删除这些列。

我只有 40k 行。我的范围、列和行每周都会扩展，所以我想使用 VBA 来减少格式化时间。

Sub test()
'start
Dim LR1 As Long
Dim i As Long
Set ws = ThisWorkbook.ActiveSheet

With ws
    LR1 = .Cells(2, .Columns.Count).End(xlToLeft).Column   
    Dim arr As Variant
    Dim x
    arr = Array("C15", "C17", "C19", "C20", "C21", "C22", "C23", "C24", "C25", "C28", "C29", "C30", "C32")

    For x = LBound(arr) To UBound(arr)
        For i = LR1 To 4 Step -1
            If .Cells(2, i).Value = arr(x) Then
            Else
                .Columns(i).Delete
            End If
        Next i
    Next x
End With
End Sub

Answer 1

除了 cmets 中提出的所有要点之外，主要问题是您的循环逻辑已关闭。你的外循环应该是列，内​​循环应该是数组。但是使用Select Case，无论如何都可以将其简化为一个循环。

大概是这样的：

Option Explicit

Sub Test()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.ActiveSheet

    With ws
        Dim lastCol As Long, i As Long
        Dim rng As Range

        lastCol = .Cells(2, .Columns.Count).End(xlToLeft).Column

        For i = lastCol To 4 Step -1
            Select Case .Cells(2, i).Value
                Case "C15", "C17", "C19", "C20", "C21", "C22", "C23", "C24", "C25", "C28", "C29", "C30", "C32"
                    ' keep
                Case Else
                    If rng Is Nothing Then
                        Set rng = .Columns(i)
                    Else
                        Set rng = Union(rng, .Columns(i))
                    End If
            End Select
        Next i

        If Not rng Is Nothing Then
            rng.Delete
        End If
    End With
End Sub