那么,XSLT 来救场了。请注意,XSLT 会让您患上眼癌——语法很糟糕,但它是为这类东西而生的。在任何情况下,结果都将比使用 awk 或 sed 处理 XML 的任何尝试更加稳健。
我们将编写一些 XSLT 代码(我稍后会讲到),将其放入文件 urlexplode.xsl,然后我们可以使用几乎所有的 XSLT 处理器来应用转换。例如,xalan:
curl -sL -d "$MC" "http://www.example.com/ne/eService.asmx" | xalan -xsl urlexplode.xsl
代码是
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="Url">
<xsl:call-template name="urlexplode">
<xsl:with-param name="count" select="ancestor::*/partCount"/>
<xsl:with-param name="urlstub" select="text()"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="urlexplode">
<xsl:param name="count" />
<xsl:param name="urlstub"/>
<xsl:if test="$count > 0">
<xsl:call-template name="urlexplode">
<xsl:with-param name="count" select="$count - 1"/>
<xsl:with-param name="urlstub" select="$urlstub" />
</xsl:call-template>
<Url><xsl:value-of select="$urlstub"/><xsl:value-of select="$count"/>.zip</Url>
<xsl:text>
 </xsl:text>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
可怕,不是吗?幸运的是,可怕的是所有语法;它比看起来简单得多。让我们分块进行。我们有三个模板(想想 XSLT 中的模板,就像其他语言中的函数一样)。第一个是
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
这是一个身份模板;本质上是一个包罗万象的处理程序,它逐字复制与另一个模板不匹配的所有内容,并在执行过程中递归地应用模板。它在那些我们不想更改的地方保持 XML 的完整性。
<xsl:template match="Url">
<xsl:call-template name="urlexplode">
<xsl:with-param name="count" select="ancestor::*/partCount"/>
<xsl:with-param name="urlstub" select="text()"/>
</xsl:call-template>
</xsl:template>
适用于Url 标签。我们没有逐字复制这些内容,而是从祖先节点中选择 partCount 和 Url 标记内的文本,然后将整个内容传递给 urlexplode 模板,该模板将完成实际工作。
<xsl:template name="urlexplode">
<xsl:param name="count" />
<xsl:param name="urlstub"/>
<xsl:if test="$count > 0">
<xsl:call-template name="urlexplode">
<xsl:with-param name="count" select="$count - 1"/>
<xsl:with-param name="urlstub" select="$urlstub" />
</xsl:call-template>
<Url><xsl:value-of select="$urlstub"/><xsl:value-of select="$count"/>.zip</Url>
<xsl:text>
 </xsl:text>
</xsl:if>
</xsl:template>
最后,这会为Url 节点生成替换内容。它递归地调用自己paramCount 次,然后生成一个新的Url 节点,其文本由我们从原始节点获取的url 存根、当前计数器和.zip 组成。它还添加了一个换行符(&#xa; 的东西),这对于保持 XML 的有效性并不是绝对必要的,但使它更易于阅读。
这可以在 XSLT 2.0(它具有更强大的循环结构)中更简单地完成,但没有任何东西支持 XSLT 2.0,所以我们坚持使用旧方法。