用gnuplot画一条最合适的曲线

Question

假设我有一组点x,y 用 gnuplot 绘制图像。它按预期工作并且我得到了一条漂亮的曲线。我想对大型图像数据集（比如 1000）重复实验。在此时，您将在一个绘图上获得 1000 条曲线，每条曲线用于一张图像。我如何告诉 gnuplot 绘制曲线的最佳拟合？

我希望 gnuplot 为我提供 csv 中最佳拟合曲线的 x,y 点，因为我计划稍后再绘制一个最佳拟合图。

数据可以查到here

Answer 1

如果我对您的理解正确，您希望通过数据绘制一条平均线，而不是拟合函数的数据。您可以使用 plot 命令的smooth 选项来执行此操作。

根据您的需要，您可以通过数据绘制插值函数。例如：

plot \
"libjpeg-2000-bench.png.csv" u 3:5 w p, \
"libjpeg-2000-mural.png.csv" u 3:5 w p, \
"libjpeg-2000-red-room.png.csv" u 3:5 w p, \
"libjpeg-bench.png.csv" u 3:5 w p, \
"libjpeg-mural.png.csv" u 3:5 w p, \
"libjpeg-red-room.png.csv" u 3:5 w p, \
 "< tail -q -n +4  libjpeg*csv" u 3:5 smooth acsplines   w l lw 2

给予

您可能想尝试各种平滑函数，请参阅help smooth。其中一些函数还需要额外的参数。例如，您可以为acsplines 插值指定权重：

plot \
"libjpeg-2000-bench.png.csv" u 3:5 w p, \
"libjpeg-2000-mural.png.csv" u 3:5 w p, \
"libjpeg-2000-red-room.png.csv" u 3:5 w p, \
"libjpeg-bench.png.csv" u 3:5 w p, \
"libjpeg-mural.png.csv" u 3:5 w p, \
"libjpeg-red-room.png.csv" u 3:5 w p, \
"< tail -q -n +4  libjpeg*csv" u 3:5:(100) smooth acsplines title "acsplines, weight = 100" w l lw 2,  \
"< tail -q -n +4  libjpeg*csv" u 3:5:(0.1) smooth acsplines title "acsplines, weight = 0.1" w l lw 2

权重的选择涉及权衡：如果权重较大，则曲线将更接近数据点，但可能会出现波动。

或者，您可以在 x 方向对数据点进行分箱，并对属于同一分箱的数据点进行平均。幸运的是，您可以在 gnuplot 中完成所有这些操作：

round(x) = floor(x+0.5)
bin(x,binwidth) = binwidth*round(x/binwidth)
binwidth = 1.
plot \
"libjpeg-2000-bench.png.csv" u 3:5 w p, \
"libjpeg-2000-mural.png.csv" u 3:5 w p, \
"libjpeg-2000-red-room.png.csv" u 3:5 w p, \
"libjpeg-bench.png.csv" u 3:5 w p, \
"libjpeg-mural.png.csv" u 3:5 w p, \
"libjpeg-red-room.png.csv" u 3:5 w p, \
 "< tail -q -n +4  libjpeg*csv"  u (bin($3,binwidth)):5 smooth uniq  w l lw 2

给予

您可以在此处根据需要调整 binsize binwidth。

Answer 2

我不得不承认，我并不完全清楚你到底想要达到什么目标，但我也有一种感觉，正如@KevinBoone 在 cmets 中提到的那样，你正试图对数据。如果是这种情况，那么很遗憾 Gnuplot 不是完成这项任务的合适工具。在我看来，将这个处理任务委托给更合适的人会更实际。

例如，假设策略确实是：

1. 加载当前目录下的所有csv文件
2. 将 x 范围划分为 M 个 bin 并计算落入每个 bin 的 y 值的平均值
3. 绘制这个“平均”数据

为此，可以根据 binned_statistic scipy 工具包提供的函数。所需数量的 bin 作为第一个参数传递，而其余参数被解释为 csv 文件进行处理：

#!/usr/bin/env python
import sys

import numpy as np
from scipy.stats import binned_statistic

num_of_bins = int(sys.argv[1])

data = []
for fname in sys.argv[2:]:    
    with open(fname, 'r') as F:
        for line_id, line in enumerate(F):
            if line_id < 3: continue

            cols = line.strip().split(',')
            x, y = map(float, [cols[i] for i in [2, 3]])
            data.append((x, y))

data = np.array(data)
stat, bin_edges, _ = binned_statistic(data[:, 0], data[:, 1], 'mean', bins = num_of_bins, range = None)

for val, (lb, ub) in zip(stat, zip(bin_edges, bin_edges[1:])):
    print('%E,%E' % ( (lb+ub)/2, val ))

现在，在 Gnuplot 中，我们可以在外部调用此脚本（假设它以 stat.py 的形式存储在当前工作目录中）并将其与各个文件一起绘制：

set terminal pngcairo enhanced
set output 'fig.png'

#get all csv files in current directory as a space-delimited string
files = system("ls *.csv | xargs")

#construct a "pretty" label from the file name
getLabel(fname)=system(sprintf('echo "%s" | gawk -F"-" "BEGIN{OFS=\"-\"} {NF=NF-2;print}"', fname))

set datafile separator ","
set key spacing 1.5

LINE_WIDTH = 1.25
plot \
    for [filename in files] filename u 3:4 w l lw LINE_WIDTH t getLabel(filename), \
    sprintf('<python ./stat.py 20 %s', files) w l lw 3*LINE_WIDTH lc rgb 'red' t 'average'

使用您在 cmets 中提供的一些示例数据，这会产生：

但是，正如@KevinBoone 所指出的那样，这个“平均值”在您的特定设置中是否具有合理的数学含义本身就是另一个问题......