F#：类型和函数之间可以相互递归吗？

Question

我可以使用and 关键字来设置相互递归的函数定义。我也可以将and 用于相互递归的类型，但是如果类型和函数之间存在相互递归的关系怎么办？我唯一的选择是让函数成为该类型的成员还是我也可以在这里使用类似于and 的东西？

编辑：添加一个简化的伪示例，希望能说明我正在尝试做的事情

// A machine instruction type
type Instruction = Add | CallMethod int (* method ID *) | ...

// A class representing a method definition
type MethodDef (fileName : string) =
    member x.Params with get () = ...
    member x.Body with get() =
        let insts = readInstructions fileName
        Array.map toAbstractInst insts

// a more abstract view of the instructions
and AbstractInstruction = AbstAdd | AbstCallMethod MethodDef | ...

// a function that can transform an instruction into its abstract form
let toAbstractInst = function
    | Add -> AbstAdd
    | CallMethod methodId -> AbstCallMethod (somehowResolveId methodId)
    | ...

所以你可以在这里看到递归关系的建立非常间接：MethodDef AbstractInst AND MethodDef -> toAbstractInst -> AbstractInstruction（其中 -> 表示“依赖于”）

Answer 1

这个问题没有例子很难回答

• 如果您有没有成员的相互递归类型，则类型不需要了解函数（因此您可以先定义类型，然后定义函数）。

• 如果你有相互递归的类型，有作为成员的函数，那么成员可以看到彼此（跨类型），你应该没问题

唯一棘手的情况是当您有相互递归的类型、相互递归的函数并且您还希望将某些函数公开为成员时。然后你可以使用类型扩展：

// Declare mutually recursive types 'A' and 'B'
type A(parent:option<B>) =
  member x.Parent = parent

and B(parent:option<A>) =
  member x.Parent = parent

// Declare mutually recursive functions 'countA' and 'countB'
let rec countA (a:A) =
  match a.Parent with None -> 0 | Some b -> (countB b) + 1
and countB (b:B) =
  match b.Parent with None -> 0 | Some a -> (countA a) + 1

// Add the two functions as members of the types
type A with 
  member x.Count = countA x

type B with 
  member x.Count = countB x

在这种情况下，你可以让countA 和countB 成为这两种类型的成员，因为这样会更容易，但如果你有更复杂的代码想要编写为函数，那么这是一个选项.

如果所有内容都写在单个模块中（在单个文件中），那么 F# 编译器会将类型扩展编译为标准实例成员（因此从 C# 的角度来看，它看起来就像普通类型）。如果您在单独的模块中声明扩展，那么它们将被编译为特定于 F# 的扩展方法。