在delphi中初始化的局部变量？

Question

在审查旧程序代码的过程中，出现了以下问题：方法中的所有局部变量都在开始后立即初始化。通常不初始化局部变量。但是我们有一个过程，其中所有变量都初始化为 0。有人知道这是怎么发生的吗？

例子：

type
  TPrices = array[0..10, 0..5] of Integer;

procedure DoSomething();
var
  mPrices : TPrices;
  mValue  : Integer; 
begin
  if (mPrices[0,0] = 0) then
    MessageDlg('Zero', mtInformation, [mbOK], 0);
  if (mValue = 0) then
    MessageDlg('Zero Integer', mtInformation, [mbOK], 0);
end;

Answer 1

这只是机会。变量未初始化。该变量将驻留在堆栈中，如果碰巧最后写入堆栈的该位置的内容为零，那么那里的值仍然为零。

非托管类型的局部变量未初始化。不要让上述巧合说服你。

考虑这个程序：

{$APPTYPE CONSOLE}

type
  TPrices = array[0..10, 0..5] of Integer;

procedure Foo;
var
  mPrices: TPrices;
begin
  Writeln(mPrices[0,0]);
end;

begin
  Foo;
end.

当我在我的机器上运行时，输出是：

1638012

现在考虑这个程序：

{$APPTYPE CONSOLE}

type
  TPrices = array[0..10, 0..5] of Integer;

procedure Foo;
var
  mPrices: TPrices;
begin
  Writeln(mPrices[0,0]);
  FillChar(mPrices, SizeOf(mPrices), 0);
end;

procedure Bar;
var
  mPrices: TPrices;
begin
  Writeln(mPrices[0,0]);
end;

begin
  Foo;
  Bar;
end.

这次的输出是：

1638012 0

碰巧这两个函数将它们的局部变量放在同一个位置，而第一个函数调用在返回之前将局部变量归零这一事实会影响第二个函数中另一个局部变量的未初始化值。

或者试试这个程序：

{$APPTYPE CONSOLE}

type
  TPrices = array[0..10, 0..5] of Integer;

procedure Foo;
var
  mPrices: TPrices;
begin
  Writeln(mPrices[0,0]);
  FillChar(mPrices, SizeOf(mPrices), 0);
  mPrices[0,0] := 666;
end;

procedure Bar;
var
  mPrices: TPrices;
begin
  Writeln(mPrices[0,0]);
  Writeln(mPrices[0,1]);
end;

begin
  Foo;
  Bar;
end.

现在的输出是：

1638012 666 0

正如您可能想象的那样，许多不同的事情都可能导致堆栈空间的内容发生变化。所以相信你所知道的。非托管类型的局部变量未初始化。