Windows Batch - 如何将外部 IP 获取到批处理文件变量中

Question

我正在制作一个程序来检查用户的 IP 是否是某个 IP 地址。

目前，我创建了一个成功的内部IP版本：

@echo off
set userIp=192.168.90.100
for /f "tokens=4 delims= " %%i in ('route print ^| find " 0.0.0.0"') do set localIp=%%i
for /f "delims=[] tokens=2" %%a in ('ping %computername% -4 -n 1 ^| findstr "["') do set thisip=%%a
goto :Check

:Check
if %localIp%==%userIp% goto :Good
if %thisip%==%userIp% goto :Good
goto :Bad

我正在尝试制作与外部 IP 相同的东西。

我在网上进行了研究，这是我目前得到的。

@echo off
for /f "tokens=2 delims=:" %%a IN ('nslookup myip.opendns.com. resolver1.opendns.com ^| findstr /IC:"Address"') do if /i %%a=="10.11.12.13" goto :Good
goto :Bad

我需要一些帮助来解决这个问题。

Answer 1

使用纯批处理/已经存在的工具：
编辑：更改批处理以正确处理 IPv6 地址

@Echo off
for /f "tokens=1* delims=: " %%A in (
  'nslookup myip.opendns.com. resolver1.opendns.com 2^>NUL^|find "Address:"'
) Do set ExtIP=%%B
Echo External IP is : %ExtIP%

Reference

另一个带powershell的：

@Echo off
For /f %%A in (
  'powershell -command "(Invoke-Webrequest "http://api.ipify.org").content"'
) Do Set ExtIP=%%A
Echo External IP is : %ExtIP%

还有另一个稍微不同的 powershell 变体：

@Echo off
For /f %%A in (
  'powershell -nop -c "(Invoke-RestMethod http://ipinfo.io/json).IP"'
) Do Set ExtIP=%%A
Echo External IP is : %ExtIP%

Answer 2

要在不进行额外解析的情况下获取您的公共 IP，请执行以下操作：

卷曲“http://api.ipify.org”

编辑：

此版本跨 windows 语言版本更可靠：

for /f "tokens=3 delims== " %%A in ('
nslookup -debug myip.opendns.com. resolver1.opendns.com 2^>NUL^|findstr /C:"internet address"
') do set "ext_ip=%%A"

Answer 3

第一个.com之后似乎有一个.太多了。

第二次使用简单的google.com 和echo %a 命令时，我得到以下信息：

" xx.xx.xx.x" 没有引号和两个前导空格！

所以你的假设永远不会是真的！

把它改成这样：if "%%a"==" xx.xx.xx.x" Goto:good 你应该没问题。