在 SAS 中，如果我有如下字符串或数组，
array x[4] $1 ('A' 'B' 'C' 'D');
我需要生成元素的所有“唯一”排列，如下所示，
[ABCD]
[ABC]
[BCD]
[ACD]
[ABD]
[AB]
[AC]
[AD]
[BC]
[BD]
[CD]
[A]
[B]
[C]
[D]
SAS 中是否有生成所有可能的数组组合的函数？
【问题讨论】：
AB 和 BA 是不同的排列但相同的组合。
假设：我相信你要找的是combinations而不是permutations，所以顺序无所谓，BA和AB是一回事。
使用call allcomb 子程序和comb 函数找出可能的组合。
在此处阅读有关allcomb 和comb 的更多信息
这里
总之——
call allcomb 子例程给出了n 元素中的可能组合，当它们中的r 被采用时，comb 函数为您提供了当一次取出 n 元素 r 时将有多少组合。data test(keep=my_string);
length my_string $50.;
array a[4] $ ('A' 'B' 'C' 'D');
n = dim(a);
do k=1 to n;
do j=1 to comb(n,k);
call allcomb(j,k,of a[*]);
do i = 1 to k;
if i=1 then do; my_string="";counter=0;end;
counter=counter+1;
my_string=cat(compress(my_string),compress(a[i]));
if counter=k then output;
end;
end;
end;
run;
【讨论】：
对此略有不同的看法是使用proc summary。
创建一个虚拟数据集。将数组的每个元素分配给一个变量，这样我们就可以将它输入proc summary：
data tmp;
array arr[*] a b c d (1 1 1 1);
run;
运行proc summary。
proc summary data=tmp noprint missing;
class a b c d;
output out=combinations;
run;
您还可以使用proc summary 中的ways 或types 语句来限制您可能需要的任何组合。
现在这样做的一个有趣的副作用是您在输出数据集中也得到了_type_ 列。在上面的示例中，将分配以下值：
D = 1
C = 2
B = 4
A = 8
因此，如果输出数据集中的_type_ 值为 13，那么我们知道该行是通过组合 A、B 和 D (8 + 4 + 1) 生成的。
【讨论】：
nway，以至于我经常忘记班级分组。我认为您不需要var、sum、dummy 或任何选项，但只有class 和output out 的默认行为应该会提供所需的输出。
这是一个快速脚本，可以在字符串中查找单个字符的组合。如果您愿意，这可以很容易地适应数组。这种方法不是使用组合函数和调用例程（all*、lex*、ran*），而是通过使用整数的二进制表示来创建排列，直到2**len。我更喜欢这种方法，因为我认为它展示了正在发生的事情，更加透明并且不会改变数组分配的顺序。
data have;
str = "123456"; output;
str = "ABCD"; output;
run;
data want;
set have;
length comb $20.;
len = length(str);
/* Loop through all possible permutations */
do _i = 0 to 2**len - 1;
/* Store the current iteration number in binary */
_bin = putn(_i, "binary" || put(len, best.) || ".");
/* Initialise an empty output variable */
comb = "";
/* Loop through each value in the input string */
do _k = 1 to len;
/* Check if the kth digit of the binary representation is 1 */
/* And if so add the kth input character to the output */
if substr(_bin, _k, 1) = "1" then
comb = cats(comb, substr(str, _k, 1));
end;
output;
end;
/* Clean up temporary variables, commented so you can see what's happening */
/* drop _:; */
run;
如果您确实想要排列，那么similar approach 可以使用数字的因子表示。但是，我建议您改用组合函数，因为转换会涉及更多。不过，这可能是一个很好的学习编码练习。
如果 SAS 有一个通过布尔模式减少字符串的功能会很棒，但它可能不会有太多用处。
bsubstr("ABCD", "1010") --> "AC"
bsubstr("ABCD", "1110") --> "ABC"
bsubstr("ABCD", "0001") --> "D"
【讨论】：
SAS 具有计算组合和排列的内置函数，allcomb 和 allperm。
ALLCOMB 函数的 SAS 文档：http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a003112305.htm
【讨论】：