Solidity 将 HEX 数字转换为 HEX 字符串

Question

我需要在solidity 智能合约中存储0xff0000 或0x00ff08（十六进制颜色表示）这种类型的值，并能够在合约中将其转换为具有相同文本字符"ff0000" 的字符串。我打算在 RSK 上部署这个智能合约。

我的想法是将这些值存储在bytes3 或简单的uint 变量中，并有一个纯函数将bytes3 或uint 转换为相应的字符串。我找到了一个可以完成这项工作并在solidity 0.4.9上工作的函数

pragma solidity 0.4.9;

contract UintToString {
    function uint2hexstr(uint i) public constant returns (string) {
        if (i == 0) return "0";
        uint j = i;
        uint length;
        while (j != 0) {
            length++;
            j = j >> 4;
        }
        uint mask = 15;
        bytes memory bstr = new bytes(length);
        uint k = length - 1;
        while (i != 0){
            uint curr = (i & mask);
            bstr[k--] = curr > 9 ? byte(55 + curr ) : byte(48 + curr); // 55 = 65 - 10
            i = i >> 4;
        }
        return string(bstr);
    }
}

但我需要更新的编译器版本（至少 0.8.0）。上述功能不适用于较新版本。

将bytes 或uint 转换为十六进制字符串 (1->'1',f->'f') 在 Solidity >=0.8.0 中有效的方法是什么？

Answer 1

以下编译，并使用 solc 0.8.7 进行了测试 它与您的原始版本相同，但有以下修改：

• constant --> pure
• returns (string) --> returns (string memory)
• byte(...) --> bytes1(uint8(...))

上述更改克服了原始函数中的所有编译时差异。 ...但是仍然存在导致此函数恢复的运行时错误：

在调试时，bstr[k--] = curr > 9 ? 行在其所在循环的最后一次迭代中触发了还原。这是因为 while 循环的设置使得 k 在其最后一次迭代中为 0。

虽然识别很棘手，但修复很简单：将递减运算符从后缀更改为前缀 - bstr[--k] = curr > 9 ?。

旁白：

问：为什么在 solc 0.4.9 中编译时没有恢复， 但是当在 solc 0.8.7 中编译相同的代码时恢复？

答：solc 0.8.0 引入了一项重大更改，其中编译器插入了 uint 上溢和下溢检查。 在此之前，需要使用SafeMath 或类似方法来完成相同的操作。 See the "Silent Changes of the Semantics" section of the solc 0.8 release notes

pragma solidity >=0.8;

contract TypeConversion {
    function uint2hexstr(uint i) public pure returns (string memory) {
        if (i == 0) return "0";
        uint j = i;
        uint length;
        while (j != 0) {
            length++;
            j = j >> 4;
        }
        uint mask = 15;
        bytes memory bstr = new bytes(length);
        uint k = length;
        while (i != 0) {
            uint curr = (i & mask);
            bstr[--k] = curr > 9 ?
                bytes1(uint8(55 + curr)) :
                bytes1(uint8(48 + curr)); // 55 = 65 - 10
            i = i >> 4;
        }
        return string(bstr);
    }
}