VBA Dateadd 格式 - 需要总分钟数

Question

我在 Microsoft Excel 中有一个用户表单，我想将其用作秒表。然而，“hh:mm”的格式不允许它超过 23:59，因为它会回到 00:00

Private Sub SpinButton2_SpinUp()

If InsertEvent.TextBox1 = vbNullString Then
InsertEvent.TextBox1 = "00:00"

Else

InsertEvent.TextBox1.Value = Format(DateAdd("n", 1,       InsertEvent.TextBox1.Value), "hh:mm")
'InsertEvent.TextBox1.Value = TimeValue("mm:ss")
'InsertEvent.TextBox1.Value = Format(InsertEvent.TextBox1.Value, "hh:mm")

End If

End Sub 

是否有任何格式化它可以作为总分钟的时钟工作？理想情况下，我需要大约 125 分钟左右（125:00），但它是否无限制也没关系。

Answer 1

您不能为此使用内置的日期/时间函数，因为您需要一个不是日期/时间的表示。

假设您想将微调器值读入文本框：

Private Sub SpinButton2_SpinUp()
    Dim minutes As Integer: minutes = Val(InsertEvent.SpinButton2.Value)
    Dim hh As Integer:      hh = minutes \ 60
    Dim mm As Integer:      mm = minutes - (hh * 60)

    InsertEvent.TextBox1.Text = Format$(hh, "00") & ":" & Format$(mm, "00")
End Sub

要使用从文本框中手动输入的值作为启动/停止点，您需要将“hh:mm”重新解析为分钟，例如在文本框退出事件中：

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If (IsNumeric(TextBox1.Text)) Then
        '// entering a number only assumes its minutes
        SpinButton2.Value = TextBox1.Text
        Exit Sub
    End If

    Dim hhmm() As String: hhmm = Split(TextBox1.Text, ":")
    If (UBound(hhmm) = 1) Then
        If (IsNumeric(hhmm(0)) And IsNumeric(hhmm(1))) Then
            SpinButton2.Value = (hhmm(0) * 60) + hhmm(1)
            Exit Sub
        End If
    End If

    SpinButton2.Value = 0
End Sub

（应该为溢出/超过 spinners .Max 属性添加错误检查）