使用 VBA 宏处理然后删除 html/xml 标签

Question

我正在遍历单元格，试图将单元格值的某些部分加粗。我有一个包含内容的单元格：

<b>This part should be bold</b> but this should not be

我可以将正确的部分加粗，但下一步是删除标签。以下行会导致问题：

    Cells.Replace What:="<b>", Replacement:="", LookAt:=xlPart, SearchOrder _
        :=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
    Cells.Replace What:="</b>", Replacement:="", LookAt:=xlPart, SearchOrder _
        :=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False

当这些行运行时（以任意顺序），整个单元格值变为粗体。更具体地说，在逐行运行之后，运行任何一行都会得到相同的结果。我是 VBA 新手，不确定是什么原因造成的。

我用来使子字符串加粗的函数是：

fCell.Characters(Start:=m, Length:=n - m + 1).Font.Bold = True

其中 fCell 被循环，m 和 n 分别是定位 和 的索引。

Answer 1

一旦您只为单元格的部分内容设置了格式，您就无法在不丢失部分格式的情况下替换整个内容。

您需要使用Characters 方法删除标签：使用Instr() 找到位置，然后将那里的文本设置为“”：

Sub tester()

    RemoveStrings Range("A1"), Array("<b>", "</b>")

End Sub

Sub RemoveStrings(c As Range, Strings)
    Dim txt, pos As Long
    For Each txt In Strings
        Do
            pos = InStr(1, c.Value, txt, vbTextCompare)
            If pos > 0 Then c.Characters(pos, Len(txt)).Text = ""
        Loop While pos > 0
    Next txt
End Sub