F# 类型约束和重载决议

Question

我正在尝试在 F# 中模拟类型类系统；我想创建对打印机，它会自动实例化对打印功能的正确调用系列。我粘贴在这里的最新尝试失败了，因为 F# 无法识别正确的重载并立即放弃：

type PrintableInt(x:int) =
  member this.Print() = printfn "%d" x

let (!) x = PrintableInt(x)

type Printer() =
  static member inline Print< ^a when ^a : (member Print : Unit -> Unit)>(x : ^a) =
    (^a : (member Print : Unit -> Unit) x)
  static member inline Print((x,y) : 'a * 'b) =
    Printer.Print(x)
    Printer.Print(y)

let x = (!1,!2),(!3,!4)

Printer.Print(x)

有什么办法吗？我是在游戏开发的环境中这样做的，所以我无法承受反射、重新输入和动态转换的运行时开销：要么我通过内联静态地这样做，要么根本不这样做:(

Answer 1

您尝试做的事情是可能的。 您可以在 F# 中模拟类型类，正如 Tomas 所说，可能不像在 Haskell 中那样惯用。我认为在您的示例中，您将类型类与鸭子类型混合在一起，如果您想采用类型类方法，请不要使用成员，而是使用函数和静态成员。

所以你的代码可能是这样的：

type Print = Print with    
  static member ($) (_Printable:Print, x:string) = printfn "%s" x
  static member ($) (_Printable:Print, x:int   ) = printfn "%d" x
  // more overloads for existing types

let inline print p = Print $ p

type Print with
  static member inline ($) (_Printable:Print, (a,b) ) = print a; print b

print 5
print ((10,"hi"))
print (("hello",20), (2,"world"))

// A wrapper for Int (from your sample code)
type PrintableInt = PrintableInt of int with
  static member ($) (_Printable:Print, (PrintableInt (x:int))) = printfn "%d" x

let (!) x = PrintableInt(x)

let x = (!1,!2),(!3,!4)

print x

// Create a type
type Person = {fstName : string ; lstName : string } with
  // Make it member of _Printable
  static member ($) (_Printable:Print, p:Person) = printfn "%s, %s" p.lstName p.fstName

print {fstName = "John"; lstName = "Doe" }
print (1 ,{fstName = "John"; lstName = "Doe" })

注意：我使用运算符来避免手动编写约束，但在这种情况下也可以使用命名静态成员。 有关此技术的更多信息here。

Answer 2

你试图做的事情是不可能的（edit:显然可以做到——但它可能不是惯用的 F#），因为约束语言无法捕获第二个Print 操作所需的约束。基本上，没有办法写出这样的递归约束：

让 C 成为一个约束，指定类型要么提供Print，要么是一个双元素元组，其中每个元素都满足 C。

F# 不支持类型类，因此大多数模拟它们的尝试将（可能）以某种方式受到限制或看起来非常不自然。在实践中，与其尝试模拟在其他语言中工作的解决方案，不如寻找一个惯用的 F# 解决方案来解决问题。

您用作示例的漂亮打印可能会使用反射或通过不仅包装整数而且还包装元组来实现。